Question

my xml looks something like this:

<units>
    <unit>
        <unitnum></unitnum>
        <Year></Year>
        <Qty></Qty>
    </unit>
</units>

I create a key to capture all the possible years. Like this:

<xsl:key name="yr" match="//Year/text()" use="." />

Then I for-each loop through the keys to get unique years. My ultimate goal is to sum the quantites like this:

<xsl:for-each select="//Year/text()[generate-id()=generate-id(key('yr',.)[1])]">
     <li>
        <xsl:variable name="varjobyear" select="."/>
        <xsl:value-of select="$varjobyear"/> - sum -
        <xsl:value-of select="sum(//unit[Year=$varjobyear]/Qty)"/>
     </li>
</xsl:for-each>

For some reason my output looks like this:

2010 - sum - 0
2011 - sum - 0
2012 - sum - 0

But what I want is for those 0’s to be the actual sum of the quantities for each year.

My best guess is that there is something wrong with the predicate [Year=$varjobyear], but I can’t figure out what it is. I have also tried [Year=string($varjobyear)] and also [Year=number($varjobyear)].

What am I doing wrong? Thanks!

Answer 1

You want something like this:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kYearByVal" match="Year" use="."/>

 <xsl:template match="Year[generate-id()=generate-id(key('kYearByVal',.)[1])]">
  <li>
    <xsl:value-of select="concat(., ' - sum - ', sum(key('kYearByVal',.)/../Qty))"/>
  </li>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

When this transformation is applied on the following XML document:

<units>
    <unit>
        <unitnum>12</unitnum>
        <Year>1922</Year>
        <Qty>3</Qty>
    </unit>
    <unit>
        <unitnum>13</unitnum>
        <Year>1922</Year>
        <Qty>8</Qty>
    </unit>
    <unit>
        <unitnum>14</unitnum>
        <Year>1999</Year>
        <Qty>5</Qty>
    </unit>
    <unit>
        <unitnum>15</unitnum>
        <Year>1999</Year>
        <Qty>7</Qty>
    </unit>
    <unit>
        <unitnum>16</unitnum>
        <Year>2003</Year>
        <Qty>3</Qty>
    </unit>
</units>

the wanted, correct result is produced:

<li>1922 - sum - 11</li>
<li>1999 - sum - 12</li>
<li>2003 - sum - 3</li>