Question

Not quite sure if I asked correctly, but basically I have an array that stores some var(int/numbers). And when I loop through the array changing the numbers of the var, at the end the number seems still unchanged. You would have a better idea of what I’m talking about base on the below code.

private var _numArray:Array = new Array()
    private var _no1:int
    private var _no2:int

    public function Main():void
    {
        _no1 = 10
        _no2 = 20
        _numArray.push(_no1)
        _numArray.push(_no2)

        while (_numArray.length)
        {
            _numArray[0] = 0
            _numArray.splice(0, 1)
        }
        trace(_no1, _no2) // still returning 10 , 20
    }

Answer 1

If you want the array to store references instead of values, you’ll need to use a non-primitive datatype. Among the primitive datatypes are int, uint, Number, Boolean and String. A non-primitive (complex) datatype is anything else.

// SpecialNumber.as

public class SpecialNumber
{
    public var value:Number;

    public function SpecialNumber(value:Number)
    {
        this.value = value;
    }
}

// Main.as

public class Main
{
    public function Main()
    {
        var no1:SpecialNumber = new SpecialNumber(5);
        var no2:SpecialNumber = new SpecialNumber(10);

        var array:Array = [no1, no2];

        array[0].value += 10;
        array[1].value += 60;

        trace(no1.value, no2.value) // Output is "15 70"
    }
}