Question

Not sure if this is a MMA bug or me doing something wrong.
Consider the following function:

plotTrace[points_] :=
 ListPlot[points,
  Joined -> True,
  PlotMarkers -> Table[i, {i, Length@points}]]

now consider passing it values generated by RandomReal. Namely, consider

RandomReal[1, {nTraces, nPointsPerTrace, 2(*constant = nDimensions*)}]. 

If nTraces is 1, then PlotMarkers are displayed for all values of nPointsPerTrace that I tried:

Manipulate[
 plotTrace[RandomReal[1, {1, nPointsPerTrace, 2}]], 
 {nPointsPerTrace, 1, 20, 1}]

If nTraces is 3 or greater, then plot markers are displayed for all values of nPointsPerTrace that I tried

Manipulate[plotTrace[RandomReal[1, {nTraces, nPointsPerTrace, 2}]],
 {nTraces, 3, 20, 1}, {nPointsPerTrace, 1, 20, 1}]

But if nTraces is exactly 2, I don’t see plot markers, no matter the value of nPointsPerTrace:

Manipulate[plotTrace[RandomReal[1, {2, nPointsPerTrace, 2}]],
 {nPointsPerTrace, 1, 20, 1}]

Hints, clues, advice would be greatly appreciated!

Answer 1

It’s treating PlotMarkers -> {1,2} as a marker and size, instead of as two markers:

In[137]:= ListPlot[{{1, 2, 3}, {4, 5, 6}}, PlotMarkers -> {1, 2}] // InputForm

Out[137]//InputForm=
Graphics[GraphicsComplex[{{1., 1.}, {2., 2.}, {3., 3.}, {1., 4.}, {2., 5.}, {3., 6.}, 
  {1., 1.}, {2., 2.}, {3., 3.}, {1., 4.}, {2., 5.}, {3., 6.}}, 
  {{{Hue[0.67, 0.6, 0.6], Inset[Style[1, FontSize -> 2], 7], 
     Inset[Style[1, FontSize -> 2], 8], Inset[Style[1, FontSize -> 2], 9]}, 
    {Hue[0.9060679774997897, 0.6, 0.6], Inset[Style[1, FontSize -> 2], 10], 
     Inset[Style[1, FontSize -> 2], 11], Inset[Style[1, FontSize -> 2], 12]}, {}}}], 
 {AspectRatio -> GoldenRatio^(-1), Axes -> True, AxesOrigin -> {0, 0}, 
  PlotRange -> {{0, 3.}, {0, 6.}}, PlotRangeClipping -> True, 
  PlotRangePadding -> {Scaled[0.02], Scaled[0.02]}}]