Question

Ok, I have written a binary search tree in OCaml.

type 'a bstree = 
    |Node of 'a * 'a bstree * 'a bstree
    |Leaf


let rec insert x = function
    |Leaf -> Node (x, Leaf, Leaf)
    |Node (y, left, right) as node -> 
        if x < y then
            Node (y, insert x left, right)
        else if x > y then
            Node (y, left, insert x right)
        else
            node

---

I guess the above code does not have problems.

When using it, I write

let root = insert 4 Leaf

let root = insert 5 root

…

Is this the correct way to use/insert to the tree?

I mean, I guess I shouldn’t declare the root and every time I again change the variable root’s value, right?

If so, how can I always keep a root and can insert a value into the tree at any time?

Answer 1

This looks like good functional code for inserting into a tree. It doesn’t mutate the tree during insertion, but instead it creates a new tree containing the value. The basic idea of immutable data is that you don’t “keep” things. You calculate values and pass them along to new functions. For example, here’s a function that creates a tree from a list:

let tree_of_list l = List.fold_right insert l Leaf

It works by passing the current tree along to each new call to insert.

It’s worth learning to think this way, as many of the benefits of FP derive from the use of immutable data. However, OCaml is a mixed-paradigm language. If you want to, you can use a reference (or mutable record field) to “keep” a tree as it changes value, just as in ordinary imperative programming.

Edit:

You might think the following session shows a modification of a variable x:

# let x = 2;;
val x : int = 2
# let x = 3;;
val x : int = 3
# 

However, the way to look at this is that these are two different values that happen to both be named x. Because the names are the same, the old value of x is hidden. But if you had another way to access the old value, it would still be there. Maybe the following will show how things work:

# let x = 2;;
val x : int = 2
# let f () = x + 5;;
val f : unit -> int = <fun>
# f ();;
- : int = 7
# let x = 8;;
val x : int = 8
# f ();;
- : int = 7
# 

Creating a new thing named x with the value 8 doesn’t affect what f does. It’s still using the same old x that existed when it was defined.

Edit 2:

Removing a value from a tree immutably is analogous to adding a value. I.e., you don’t actually modify an existing tree. You create a new tree without the value that you don’t want. Just as inserting doesn’t copy the whole tree (it re-uses large parts of the previous tree), so deleting won’t copy the whole tree either. Any parts of the tree that aren’t changed can be re-used in the new tree.

Edit 3

Here’s some code to remove a value from a tree. It uses a helper function that adjoins two trees that are known to be disjoint (furthermore all values in a are less than all values in b):

let rec adjoin a b =
    match a, b with
    | Leaf, _ -> b
    | _, Leaf -> a
    | Node (v, al, ar), _ -> Node (v, al, adjoin ar b)

let rec delete x = function
    | Leaf -> Leaf
    | Node (v, l, r) ->
        if x = v then adjoin l r
        else if x < v then Node (v, delete x l, r)
        else Node (v, l, delete x r)

(Hope I didn’t just spoil your homework!)