Question

OK I’m a complete newbie to ASP.

I have a client with different content loading depending on what is passed in an array.

select case lcase(arURL(4))

Sometimes though, arURL(4) might be empty, in them cases I’m getting the following error:

Error running function functionName(), the error was:

Subscript out of range

Does anybody know a way to fix this?

Thanks

OK further code as requested. It is horrible code and I don’t mean to cause anybody a headache, so please excuse it. Thanks again ……..

function GetContent()
    dim strURL, arURL, strRetval
    select case lcase(request.ServerVariables("URL"))
        case "/content.asp"
            strURL = ""
            arURL = split(request.querystring("url"), "/")
            if request("page") = "" then
                select case lcase(arURL(2))
                    case "searches"
                        select case lcase(arURL(1))
                            case "looking"
                                select case lcase(arURL(3))
                                    case "ohai"
                                        strRetval = "Lorem"
                                    case "blahblah"
                                        strRetval = "Lorem Ipsum"                        
                                    case "edinburgh"
                                        select case lcase(arURL(4))
                                            case "ohai"
                                                strRetval = "Ipsum"
                                            case "ohno"
                                                strRetval = "Lorem"
                                        end select
                                    case "bristol"
                                        select case lcase(arURL(4))
                                            case "some_blahblah"
                                                strRetval = "LOREM"
                                            case "overthere"
                                                strRetval = "LOREM"
                                            case "blahblah"
                                                strRetval = "LOREM"
                                        end select
                                    case "cambridge"
                                        select case lcase(arURL(4))
                                            case "some_rubbish"
                                                strRetval = "Lorem"
                                        end select
                                    case else
                                        strRetval = " "
                                end select
                            case else
                                strRetval = " "
                        end select
                    case else
                        strRetval = " "
                end select 
            end if
    end select 
    strRetval = strRetval & "<style>h2{border: 0px);</style>"
    GetContent = strRetval
end function

Answer 1

You are using value passed over the querystring and split it by “/” character – when the value does not contain “enough” slashes, you will get error and the code will crash.

For example, if the querystring parameter url will be only “/something” then even arURL(2) will fail since the array has only two items. (First one is empty string, second is “something”)

To avoid all this mess, best way I can advice is writing custom function that will take array and index as its arguments and return either the item in the given index if exists otherwise empty string:

Function GetItemSafe(myArray, desiredIndex, defValue)
    If (desiredIndex < LBound(myArray)) Or (desiredIndex > UBound(myArray)) Then
        If IsObject(defValue) Then
            Set GetItemSafe = defValue
        Else  
            GetItemSafe = defValue
        End If
    Else  
        If IsObject(myArray(desiredIndex)) Then
            Set GetItemSafe = myArray(desiredIndex)
        Else  
            GetItemSafe = myArray(desiredIndex)
        End If
    End If
End Function

(ended up with more generic version, letting the calling code decide what is the default value in case index is out of array range)

Having this, change your code to use the function instead of accessing the array directly.

This line for example:

select case lcase(arURL(2))

Should become this instead:

select case lcase(GetItemSafe(arURL, 2, ""))

Change the rest of those lines accordingly and you’ll no longer get errors when the given value won’t be valid.