Question

Ok. Is it easy to copy an XML file using XSLT and create an exact copy but without any values. Basically I just want the layout.
ie

<rootnode lang="EN">
    <child1>Hello</child1>
    <child2>
        <child2_1>hello</child2_1>
    </child2>
</rootnode>

and output

<rootnode lang="">
    <child1></child1>
    <child2>
        <child2_1></child2_1>
    </child2>
</rootnode>

Answer 1

This simple modification of the identity rule:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="@*">
  <xsl:attribute name="{name()}" namespace="{namespace-uri()}"/>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

when applied on the provided XML document:

<rootnode lang="EN">
    <child1>Hello</child1>
    <child2>
        <child2_1>hello</child2_1>
    </child2>
</rootnode>

produces the wanted, correct result:

<rootnode lang="">
   <child1/>
   <child2>
      <child2_1/>
   </child2>
</rootnode>