Question

Please consider :

dalist = {{379, 219, 228, 401}, {387, 239, 230, 393},      
          {403, 238, 217, 429}, {377, 233, 225, 432}}

BarChart[dalist, 
         Frame -> True, 
         FrameTicks -> {{None, None}, {None, None}}]

I can`t figure out the way to deal with the ticks themselves and the range (the numbers). I would like to see the Range but not the ticks like the below :

EDIT :

Having solved some problem, it seems I created new ones.
To Summarize, I would like to see :
TicksLabel but not the Ticks (solved)
FrameLabel but not the Frame.

The Below shall illustrate the problem. FrameStyle control the Frame Label.
So applying opacity[0] to FrameStyle to hide the frame hides the frame Label.

BarChart[Range[10],
 ChartStyle -> Black,
 PlotRangePadding -> 0,
 Frame -> {{True, False}, {True, False}},
 FrameLabel -> {{"Why?", None}, {"Because !", None}},
 FrameTicksStyle -> Opacity[1],
 FrameStyle -> Opacity[0],

 PlotLabel -> Style["Bonjour", Bold, 16, Opacity[1]],
 LabelStyle -> Directive[Black, Bold, 12, Opacity[1]],
 ImageSize -> 400]

Answer 1

Ticks and FrameTicks have optional more complex syntax, where each tick can be specified as {x,label,{length_inside,length_outside}}

So to have ticks labels without ticks, specify the second pair of numbers as two zeros.
To replicate the ticks in your example, you would use

FrameTicks->{{Table[{j,j,{0,0}},{j,0,300000,50000}],None},
 {Table[{k,k,{0,0}},{k,2010,2015}],None}}

For BarCharts, the bars are at 1, 2, 3… x-positions, so this needs to be:

FrameTicks->{{Table[{j,j,{0,0}},{j,0,300000,50000}],None},
 {Table[{k,k+2009,{0,0}},{k,1,6}],None}}

As requested in comments, if you want numbers but no ticks and no frame, add:

FrameTicksStyle -> Opacity[1], FrameStyle -> Opacity[0]

EDIT And use Style on any frame labels.

End result:

data = RandomReal[{0, 300000}, {10}]
BarChart[data, 
 FrameTicks -> {{Table[{j, j, {0, 0}}, {j, 0, 300000, 50000}], 
 None}, {Table[{k, k + 2009, {0, 0}}, {k, 1, 10}], None}}, 
 Frame -> True, FrameTicksStyle -> Opacity[1], FrameStyle -> Opacity[0],
 FrameLabel -> {{Style["Why?", Opacity[1]],  None}, 
   {Style["Axes", Opacity[1]], None}}]

My answer to this question might help illuminate.