Question

Please explain what exactly the difference of $_ and @_ is in Perl.
When to use which, given by example code.

Answer 1

When in a subroutine, the array @_ gives the arguments passed to the given subroutine. For example:

use strict;
use warnings;

sub print_em
{
  foreach my $arg (@_)
  {
    print "You passed in $arg.\n";
  }
}

print_em("foo","bar","baz");

The output is

You passed in foo.
You passed in bar.
You passed in baz.

The scalar $_ is usually used as a variable within a loop. For example:

use strict;
use warnings;

# Note that we are not declaring a variable
# that takes on the values 1 through 5.
foreach(1..5) 
{
  print "$_\n";
}

The output is:

1
2
3
4
5

Likewise, we could have slightly rewritten the subroutine print_em above as

sub print_em
{
  foreach(@_)
  {
    print "You passed in $_.\n";
  }
}

or even as the more compact

sub print_em{ print "You passed in $_.\n" foreach(@_);}

The variable $_ can also be used as a “default argument” for certain functions. For example:

use strict;
use warnings;

$_="foobar";

if(/bar/) #We do not have to write $_=~/bar/
{
  print "matched!\n";
}

which, of course, outputs matched!.

Take a look at perldoc perlvar for more information on these and Perl’s other “magic variables”.