Question

Please help me encode a string to correct format using xslt.

My case is: I have a xml file which i need to convert it to JSON text, I see a lot of single quotes with in the string in xml & resulting JSON structure is not proper. how to handle this?

<line>brother's sister's</line>

Should result in a JSON something like

{"line": "brother%25s sister%25s"}

Answer 1

You can use recursion to replace ' to %25, e.g.:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
    <xsl:variable name="apos">'</xsl:variable>

    <xsl:template match="line">
        <xsl:call-template name="replace">
            <xsl:with-param name="input" select="."/>
            <xsl:with-param name="from" select="$apos"/>
            <xsl:with-param name="to" select="'%25'"/>
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="replace">
        <xsl:param name="input"/>
        <xsl:param name="from"/>
        <xsl:param name="to"/>

        <xsl:choose>
            <xsl:when test="contains($input, $from)">
                <xsl:value-of select="substring-before($input, $from)"/>
                <xsl:value-of select="$to"/>

                <xsl:call-template name="replace">
                    <xsl:with-param name="input" select="substring-after($input, $from)"/>
                    <xsl:with-param name="from" select="$from"/>
                    <xsl:with-param name="to" select="$to"/>
                </xsl:call-template>

            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$input"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>