Question

Please, may somebody explain me, what can raise an exception in this code?

function CreateBibleNames: TStrings;
begin
  Result := TStringList.Create;
  try
    Result.Add('Adam');
    Result.Add('Eva');
    Result.Add('Kain');
    Result.Add('Abel');
  except
    Result.Free;
    raise;
  end;      
end;

Since I use delphi I have used exception handling perhaps once. I consider the code above to be written by a skillfull programmer and I do not think the exceptions are redundant. But still, using exception handling in this concept remains a mystery for me. It seems to be a safe code (without try except end). I have seen many times similar code snippets like this, that’s why there is probably a good reason to write it this way in spite of my experience, that did not prove it’s necessity.

Moreover when something fails, I get exception description….

Thanx

Answer 1

Okay, that code is strange, I agree, and I totally understand why it got written that way. But it was written that way because the premise underlying the code is wrong. The fact that the construct seems strange should be a “code smell”, and should tell you that something might not be getting done the best way possible.

First, here’s why the unusual construct in the try…except block. The function creates a TStringList, but if something goes wrong in the course of filling it, then the TStringList that was created will be “lost” out on the heap and will be a memory leak. So the original programmer was defensive and made sure that if an exception occurred, the TStringList would be freed and then the exception would get raised again.

Now here is the “bad premise” part. The function is returning an instance of TStrings. This isn’t always the best way to go about this. Returning an instance of an object like that begs the question “Who is going to dispose of this thing I’ve created?”. It creates a situation where it might be easy — on the calling side — to forget that a TStrings instance has been allocated.

A “Better Practice” here is to have the function take a TStrings as a parameter, and then fill in the existing instance. This way, there is no doubt about who owns the instance (the caller) and thus who should manage its lifetime.

So, the function becomes a procedure and might look like this:

procedure CreateBibleNames(aStrings: TStrings);
begin
  if aStrings <> nil then
  begin
    aStrings .Add('Adam');
    aStrings .Add('Eva');
    aStrings .Add('Kain');
    aStrings .Add('Abel');
  end;      
end;

Now this is not to say that returning an object instance is a bad thing every time — that is the sole function of the very useful Factory pattern, for example. But for more “general” functions like this, the above is a “better” way of doing things.