Question

Possible Duplicate:
How can I produce a PDF file using data in an XML file, in Perl?

I have xml tags that stored in a hash as shown below.

$var1={
     'stud.xml'={ 
                '24'=>'<address>
                        <streetname="xxxx"/>
                         <housenum="138"/">
                        </address>'
                 '20'=>'<address>
                       <streetname="xxxx"/>
                        <housenum="110"/">
                       </address>'
                     }...........

now I need to convert into pdf by using perl script. I searched and I found PDF::API2 is best module to convert into pdf. After reading module I am able to create new pdf file and set some settings like font, format,like….but I can’t understand how to process this xml data into pdf.

Answer 1

Create a LaTeX template, populate the template using the data, and then run pdflatex on it.

Note that the XMLish thing you posted is not helpful. Either post the actual XML or the Perl data structure.

Here is an example:

#!/usr/bin/env perl

use warnings; use strict;
use HTML::Template;
use XML::Simple;

my $xml = <<'EO_XML';
<students>
    <student id="24">
        <address>
            <streetname val="xxxx"/>
            <housenum val="138" />
        </address>
    </student>
    <student id="20">
        <address>
            <streetname val="xxxx"/>
            <housenum val="110" />
        </address>
    </student>
</students>
EO_XML

my $data = XMLin($xml)->{student};

my @loop_data;

for my $student (values %$data) {
    my $address = $student->{address};
    push @loop_data, {
        HOUSENUM => $address->{housenum}{val},
        STREETNAME => $address->{streetname}{val},
    };
}

my $tmpl = HTML::Template->new(filehandle => \*DATA);

$tmpl->param(STUDENTS => \@loop_data);
$tmpl->output(print_to => \*STDOUT);

__DATA__
\documentclass{article}

\begin{document}

<TMPL_LOOP STUDENTS>
<TMPL_VAR HOUSENUM> <TMPL_VAR STREETNAME>

</TMPL_LOOP>
\end{document}