Question

Possible Duplicate:
How to make a type with restrictions

Is it possible in Haskell to create a type for example “Name” which is a String but containing no more then 10 letters?

If not how can I forbid to create a Person with to long name (where Person is defined like that: data Person = Person Name).

Maybe it is not important at all, maybe that kind of problems should be solved in Haskell in a different way?

Answer 1

Don’t export the constructor from the module where you define the type, and instead export a “smart constructor”:

module Name (Name(), -- exports the type Name, but not the data constructor Name
             nameFromString,
             stringFromName)
where

data Name = Name String

-- this is the only way to create a Name
nameFromString :: String -> Maybe Name
nameFromString s | 10 < length s = Nothing
                 | otherwise     = Just (Name s)

-- this is the only way to access the contents of a Name
stringFromName :: Name -> String
stringFromName (Name s) = s

---

So you’re concerned that if you previously had code that didn’t require names to be limited to ten characters, you can’t just drop in nameFromString as it has type String -> Maybe Name instead of String -> Name.

First, if you really want to throw an exception, you can define

import Data.Maybe (fromMaybe)

nameFromString' :: String -> Name
nameFromString' = fromMaybe (error "attempted to construct an invalid Name") . nameFromString

and use that instead.

Second, throwing an exception is sometimes the wrong thing to do. Consider

askUserForName :: IO Name
askUserForName
   = do putStr "What's your name? (10 chars max)  "
        s <- getLine
        case nameFromString s of
            Just n  -> return n
            Nothing -> askUserForName

Rewriting this to use exceptions would result in more complex code.