Question

Possible Duplicate:
Issue with displaying SQL result in DataGridView

I’ve kind of asked this question before but never got it sorted. Basically I am trying to populate a datagridview on my form with the results of an SQL query. I get no errors from this code but I do just get a completely blank datagridview i.e it does not show a thing, not even the column headings.

Also please note I know im currently open to SQL injection on my sql, I just want to get this working before I sort that.

Here is my whole class code:

Imports System.Data.OleDb
Imports System.Data

Public class TechScreen_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

Dim con As OleDbConnection = New OleDbConnection("Provider=Microsoft.Jet.OLEDB.4.0: Data Source = C:\Users\Dave\Documents\jobList.mdb;")
Dim cmd As OleDbCommand = New OleDbCommand("SELECT * FROM jobList WHERE techID = " &  TechScreenID &"", con)
con.Open()
Dim DA As OleDbDataAdapter = New OleDbDataAdapter(cmd)
Dim mydataset As DataSet = New DataSet
DA.Fill(mydataset, "MyTable")
DataGridView1.DatSource = mydataset.Tables("MyTable").DefaultView
con.Close()
con = Nothing

End sub
End class

Answer 1

First off, while it may or may not be the source of your problem, the line:

DataGridView1.DatSource = mydataset.Tables("MyTable").DefaultView

Contains a typo. Should be DataGridView1.DataSource. Seems like this would have caused a compiler error though.

Other than that, try simplifying things similar to the below, and if you still have the binding problem, step through in the debugger to make sure everything is working as expected. Also, check that the “Autogenerate Columns” property on your dgv control is set to true.

I am not clear on some of what you are trying to do, so the following is a very general example of how I would approach this.

• First off, move your connection string to the project settings file,
  and use My.Settings.MyConnectionStringName to refer to it.
• Second, use Parameters in your SQL, instead of in-line concatenation.
• Wrap your data access stuff in “Using” Blocks. Using will handle
  disposal of objects within the blocks scope for you, and is generally
  a cleaner way to go.
• Just my personal preference, but I don’t like all the bs overhead
  that comes with Data Sets which a simple data table will do.
• I didn’t do it here as fully as possible here, but I recommend
  separating the data retrieval from assignment to a UI control. Even
  more, I would probably go the next step, and separate the control
  assignment from the Form Load event as well. You may well find that
  there are multiple places in your form which require the datasource
  to refresh or reset.

There are a variety of ways to approach this, and mine is not necessarily the “popular way. However, the following worked for me just now.

Simplify your code, and employ some refactoring:

Imports System.Data
Imports System.Data.OleDb

Public Class TechScreen

    Private Sub TechScreen_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load

        'Not sure where your TechScreenID input parameter is coming from, so this is just for example:
        Dim TechID As Integer = 1

        ' Use a function to return the data to be used as the DataSource for the dgv control:
        DataGridView1.DataSource = Me.JobListTable(TechID)

    End Sub


    Private Function JobListTable(TechID As Integer) As DataTable
        Dim dt As DataTable = Nothing

        Dim SQL As String = "SELECT * FROM joblist WHERE techID = @TechID"

        ' The Using block handles disposal of objects initialized:
        Using con As OleDbConnection = New OleDbConnection(My.Settings.MyConnection)
            Using cmd As OleDbCommand = New OleDbCommand(SQL, con)

                ' Use parameters instead of inline concatenation for cleaner code,
                ' and protection against sql injection attacks:
                cmd.Parameters.AddWithValue("@TechID", TechID)
                con.Open()

                dt = New DataTable()

                Try
                    dt.Load(cmd.ExecuteReader())
                Catch
                    MsgBox("There was an error retrieving data")
                Finally
                    con.Close()
                End Try
            End Using
        End Using

        Return dt

    End Function

End Class