Question

Possible Duplicate:
Simplest way to do a recursive self-join in SQL Server?

I have to create a table in SQL that will comprise of groups of items/products. Each new group made will be made under one of the pre-defined groups or the groups previously formed. I want to keep all this data in a SQL Table. So far, I have though of creating a table like this:

• Group ID
• Group Name
• Group Under (This will store the ID of the group under which this group is from

But this can only refer to just the next level, how will I get to know who is the super-parent of this group.

For example:

• I have groups A, B, C.
• A has further subgroups A1, A2, A3.
• A1 has further subgroups, A11, A12, A13.

I will I have the information about super-parent group i.e A from A11 or A22 or A33?

Let me know if the problem is not clear..

Answer 1

Assuming T-SQL and MSSQLServer (you didn’t specify), and given that your Group table should look something like this:

Id | Name | ParentId
---+------+---------
 1 | A    | NULL
 2 | B    | NULL
 3 | C    | NULL
 4 | A1   | 1
 5 | A2   | 1
 6 | A3   | 1
 7 | A11  | 4
 8 | A12  | 4
 9 | A13  | 4

You can use the following recursive CTE to find the top level a given group, say ‘A12’:

WITH [Group](Id, Name, ParentId) AS
(
    SELECT 1, 'A'  , NULL UNION
    SELECT 2, 'B'  , NULL UNION
    SELECT 3, 'C'  , NULL UNION
    SELECT 4, 'A1' , 1    UNION
    SELECT 5, 'A2' , 1    UNION
    SELECT 6, 'A3' , 1    UNION
    SELECT 7, 'A11', 4    UNION
    SELECT 8, 'A12', 4    UNION
    SELECT 9, 'A13', 4

), q AS 
(
    SELECT  
        *
    FROM    
        [Group]
    WHERE
        [Name] = 'A12' -- Given 'A12' as the child
    UNION ALL
    SELECT  
        g.*
    FROM
        [Group] g
    JOIN    
        q
        ON      
        q.ParentId = g.Id
    )
SELECT  
    *
FROM
    q
WHERE
    ParentId IS NULL

This query returns:

Id | Name | ParentId
---+------+---------
 1 | A    | NULL