Question

Possible Duplicate:
T-SQL: Opposite to string concatenation – how to split string into multiple records
Splitting variable length delimited string across multiple rows (SQL)

I have a database table that contains column data like this:

Data (field name)
1111,44,666,77
22,55,76,54
32,31,56

I realise this is a very poor design because it is not normalised (I didn’t design it – I inherited it). Is there a query that will return the data like this:

1111
44
666
77
22
55
76
54
32
31
56

I am use to using CHARINDEX and SUBSTRING, but I cannot think of a way of doing this as the number of elements in each cell (delimited by a comma) is unknown.

Answer 1

You can use CTE to split the data:

;with cte (DataItem, Data) as
(
  select cast(left(Data, charindex(',',Data+',')-1) as varchar(50)) DataItem,
         stuff(Data, 1, charindex(',',Data+','), '') Data
  from yourtable
  union all
  select cast(left(Data, charindex(',',Data+',')-1) as varchar(50)) DataItem,
    stuff(Data, 1, charindex(',',Data+','), '') Data
  from cte
  where Data > ''
) 
select DataItem
from cte

See SQL Fiddle with Demo

Result:

| DATAITEM |
------------
|     1111 |
|       22 |
|       32 |
|       31 |
|       56 |
|       55 |
|       76 |
|       54 |
|       44 |
|      666 |
|       77 |

Or you can create a split function:

create FUNCTION [dbo].[Split](@String varchar(MAX), @Delimiter char(1))       
returns @temptable TABLE (items varchar(MAX))       
as       
begin      
    declare @idx int       
    declare @slice varchar(8000)       

    select @idx = 1       
        if len(@String)<1 or @String is null  return       

    while @idx!= 0       
    begin       
        set @idx = charindex(@Delimiter,@String)       
        if @idx!=0       
            set @slice = left(@String,@idx - 1)       
        else       
            set @slice = @String       

        if(len(@slice)>0)  
            insert into @temptable(Items) values(@slice)       

        set @String = right(@String,len(@String) - @idx)       
        if len(@String) = 0 break       
    end   
return 
end;

Which you can use when you query and this will produce the same result:

select s.items declaration
from yourtable t1
outer apply dbo.split(t1.data, ',') s