Question

Previously i have static array for the matrix dataset design

TMatrix = record
    row, column: word; {m columns ,n strings }
    Data: array[1..160, 1..160] of real

 var
 Mymatrix  : TMatrix;

 begin

 Mymatrix.row := 160; - maximum size for row us is 160 for 2 x 2 static design.
 Mymatrix.columns := 160; -  maximum size for column us is 160  for 2 x 2 static design.

With the current design i can only have 160 x 160 in 2 dimensional matrix design. If i enter more array size [1..161, 1..161] , the compiler will alert for E2100 Data type too large: exceeds 2 GB error. So if i convert the code into dynamic array , i need to re-structure all my current code to read the matrix starts from 0 . Previoulsy , for static array the array will starts from 1. Some external functions it start to read the matrix from 1.

So , now i’m stuck with my current code which i need to create more than thousand N x N matrix size . With my current static array design everything went fine if below than 160 x 160 . So , i need to get any solutions without too much to change my current static array design.

Thanks.

Answer 1

It’s going to be easier to continue using 1-based indexing. You can do that a few different ways. For example:

type
  TMatrix = record
  private
    Data: array of array of Real;
    function GetRowCount: Integer;
    function GetColCount: Integer;
    function GetItem(Row, Col: Integer): Real;
    procedure SetItem(Row, Col: Integer; Value: Real);
  public      
    procedure SetSize(RowCount, ColCount: Integer);
    property RowCount: Integer read GetRowCount;
    property ColCount: Integer read GetColCount;
    property Items[Row, Col: Integer]: Real read GetItem write SetItem; default;
  end;

function TMatrix.GetRowCount: Integer;
begin
  Result := Length(Data)-1;
end;

function TMatrix.GetColCount: Integer;
begin
  if Assigned(Data) then
    Result := Length(Data[0])-1
  else
    Result := 0;
end;

procedure TMatrix.SetSize(RowCount, ColCount: Integer);
begin
  SetLength(Data, RowCount+1, ColCount+1);
end;

function TMatrix.GetItem(Row, Col: Integer): Real;
begin
  Assert(InRange(Row, 1, RowCount));
  Assert(InRange(Col, 1, ColCount));
  Result := Data[Row, Col];
end;

procedure TMatrix.SetItem(Row, Col: Integer; Value: Real);
begin
  Assert(InRange(Row, 1, RowCount));
  Assert(InRange(Col, 1, ColCount));
  Data[Row, Col] := Value;
end;

The trick here is that even though the dynamic array uses 0 based indexing, you simply ignore the values stored in the 0 index. If ever you are porting code from Fortran which uses 1-based indexing, this approach is generally the most effective.