Question

Private Sub framePDF_MouseMove(ByVal... )
framePDF.BackColor = &H80000012&  

So, the frame’s color is changing.
I can’t find the event to return the color back – when the cursor is away from the frame ?

Answer 1

In vba and VB6 there is no MouseLeave event.

The best way to achieve this is to start a timer when the mouse enters the frame.

Then in the timer code check to see if the mouse pointer is still within the bounds of the frame. If not change the colour back and stop the timer

Put this code in a module:

Public Declare Function GetCursorPos Lib "user32" (lpPoint As _
   POINTAPI) As Long

Public Type POINTAPI
        x As Long
        y As Long
End Type

Create a timer on your form, set interval =10 Enbaled = False

Then the code looks something like this:

Private Sub frameTest_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
    frameTest.BackColor = vbRed
    tmrMouseLeave.Enabled = True
End Sub

Private Sub tmrMouseLeave_Timer()
    Dim pt As POINTAPI
    Call GetCursorPos(pt)
    Dim xValue As Long, yValue As Long
    xValue = pt.x * Screen.TwipsPerPixelX
    yValue = pt.y * Screen.TwipsPerPixelY

    If (xValue > (Me.Left + frameTest.Left)) And _
       (xValue < (Me.Left + frameTest.Left + frameTest.width)) And _
       (yValue > (Me.Top + frameTest.Top)) And _
       (yValue < (Me.Top + frameTest.Top + frameTest.height)) Then
        'we are still inside the frame
    Else
        'mouse is outside the frame
        frameTest.BackColor = vbBlue
        tmrMouseLeave.Enabled = False
    End If
End Sub