Question

public function create():ArrayCollection{

            var index:int = 0;
            var data:ArrayCollection = new ArrayCollection();
            var length:int = originalData.length;

            for(index; index < length; index++){
                data.addItem(originalData[index]);
            } 

            return data;
        }

• originalData is the original state of my data from database.
• data is a copy of originalData used to be manipulated as the provider for my List component.
• There’s a button I use to call the create() function above, that
  would mean, I want to revert all changes in data, and go back to
  everything I have in originalData.

But when I debug my function, originalData has all the changes made in data.

When I use

list.selectedItem.thing = “new string”;

is supposed to modify data[index].thing, because data is my List.dataprovider. but it changes originalData[index].thing also and this collection wasn’t used for anything, except for creating a copy of itself!

I don’t know why this happens. I didn’t know how to phrase this behaviour as a google query.

Please, if you don’t understand the question, comment it so I can try and make it clearer. This has consumed more time than its functionality is worth.

EDIT:

I’ve also tried this, but it doesn’t work:

public function create():ArrayCollection{

            var index:int = 0;
            var data:ArrayCollection = new ArrayCollection();
            var length:int = originalData.length;

            for(index; index < length; index++){
// initializing a Item object.
                var dataItem:Item = new Item();
                dataItem = originalData[index] as Item;
                data.addItem(dataItem);
            } 

            return data;
        }

EDIT 2:

Based on your answers and some research I came up with this generic function to copy arrayCollections made of custom objects.

public static function copy(objectClassName:String, objectClass:Class, arrayCollection:ArrayCollection):ArrayCollection{
            var index:int = 0;
            var length:int = arrayCollection.length;
            var copy:ArrayCollection = new ArrayCollection();

            for(index; index < length; index++){
                registerClassAlias(objectClassName,objectClass);
                copy.addItemAt(ObjectUtil.copy(arrayCollection.getItemAt(index)) as objectClass,index);
            }
            return copy;
        }

Answer 1

As Tom says, this is because AS3 passes by reference. If you don’t want to modify the original values then you should, again as Tom says, create copies of them.

Fortunately, AS3 has a utility to do this — ObjectUtils.copy. Try this code instead of your original:

public function create():ArrayCollection{

            var index:int = 0;
            var data:ArrayCollection = new ArrayCollection();
            var length:int = originalData.length;

            for(index; index < length; index++){
                data.addItem(mx.utils.ObjectUtil.copy(originalData[index]));
            } 

            return data;
        }

Do take note that copy() returns a generic Object. If you want to access any of its properties in a type-safe manner you’ll have to cast it to its type.

A bit more about the pass-by-reference deal. Let’s say we have items a, b, and c floating around in memory. You put them into an array(originalData). originalData now contains references to a, b, and c. You then create an ArrayCollection and insert (again) references to a, b, c. Objects a, b, and c aren’t what’s being stored in either the array or the ArrayCollection. So when you update originalData[0] you’re getting a reference to an object (a), and updating it.

Likewise when you update ArrayCollection.getItemAt(0) you’re getting the same reference and updating the underlying object which is why you’re getting the behavior you’re getting. Making a copy and inserting it means you’re referencing an entirely new object.