Question

Recently I came across this Perl expression on a blog, unable to grab it purpose.

    my $success = 1; 
    $success &&= $insert_handle->execute($first, $last, $department); 
    $success &&= $update_handle->execute($department);

Answer 1

EXPR1 &&= EXPR2;

is short for

EXPR1 = EXPR1 && EXPR2;

(Except that EXPR1 is only evaluated once.*)

The provided code

my $success = 1; 
$success &&= $insert_handle->execute($first, $last, $department); 
$success &&= $update_handle->execute($department);

could also have been written as:

my $success = 0;
if ($insert_handle->execute($first, $last, $department)) {
   if ($update_handle->execute($department)) {
      $success = 1;
   }
}

or

my $success = $insert_handle->execute($first, $last, $department)
           && $update_handle->execute($department);

---

* — This matters if EXPR1 has side-effects, which could very well happen if it’s a magical variable or an lvalue sub.

my $x = 3;      # Prints:
print("$x\n");  # 3

sub x() :lvalue { print("x\n"); $x }

x &&= 4;        # x
print("$x\n");  # 4

x = x && 5;     # x x
print("$x\n");  # 5