Question

Requirement : Get the All users in the Login Table + and their LATEST Login Record from UserLogin Table for provided tenant

Current Query :

SELECT [USER].UserName , UserLogin.AttemptDate , UserLogin.LogoutDate
FROM [User] LEFT JOIN UserLogin 
ON [User].UserId = UserLogin.UserId 
WHERE  [User].TenantId=3 
ORDER BY UserLogin.LogoutDate desc

Issue : Repeats the User Name not Distinct

Answer 1

It seems that each UserId has more than one match in UserLogin, you have to prioritize records for a given UserId from the UserLogin and choose the one that you want in the result set:

SELECT [USER].UserName , x.AttemptDate , .LogoutDate
FROM [User] 
LEFT JOIN 
(
    SELECT  *,
            ROW_NUMBER() OVER (PARTITION BY UserId ORDER BY <PriorityCondition>) Priority
    FROM    UserLogin 
) x

ON [User].UserId = x.UserId AND x.Priority = 1
WHERE  [User].TenantId=3 
ORDER BY x.LogoutDate desc

Like in this example:

DECLARE @User TABLE (UserId INT, UserName VARCHAR(100), TenantId INT)
INSERT @User VALUES (1, 'a', 3), (2, 'b', 3)

DECLARE @UserLogin TABLE (UserId INT, UserName VARCHAR(100), AttemptDate DATETIME, LogoutDate DATETIME)
INSERT @UserLogin VALUES (1, 'a', GETDATE(), GETDATE()), 
(2, 'b', GETDATE(), GETDATE()),
(2, 'b', GETDATE(), DATEADD(DAY, -1, GETDATE()))


SELECT y.UserName , x.AttemptDate , x.LogoutDate
FROM @User y
LEFT JOIN 
(
    SELECT  *,
            ROW_NUMBER() OVER (PARTITION BY UserId ORDER BY LogoutDate DESC) Priority
    FROM    @UserLogin 
) x 
ON y.UserId = x.UserId AND x.Priority = 1
WHERE  y.TenantId=3 
ORDER BY x.LogoutDate DESC