Question

<root>
<tag>
  <form>
   some html form will be here
  </form>

</tag>
<tag>
  some visible data
</tag>

xslt

<xsl:template match="tag">
    <div id="page-base">
      <xsl:apply-templates />
    </div>
  </xsl:template>

produce

<div id="page-base">

</div>
<div id="page-base">
 some visible data
</div>

Desired output

<div id="page-base">
 <form>
   some html form will be here
  </form>
</div>
<div id="page-base">
 some visible data
</div>

EDIT:

What if tag is nested in tag element where the templates rules applies it will replace the tag with the templates and will copy other element where templates does not match. please see the example. tag could be aribtrary nested

<root>
        <tag>
          <form>
           some html form will be here
          </form>
          <tag>
            arbitrary nested tags
          </tag>    
        </tag>
        <tag>
          some visible data
        </tag>
</root>

expected result

 <div id="page-base">
     <form>
       some html form will be here
      </form>
      <div id="page-base">
       arbitrary nested tags  
      </div>
  </div>
  <div id="page-base">
     some visible data
  </div>

Answer 1

This transformation:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="tag">
  <div id="page-base">
    <xsl:copy-of select="node()"/>
  </div>
 </xsl:template>
</xsl:stylesheet>

when applied on the provided XML document:

<root>
    <tag>
        <form>
   some html form will be here
        </form>
    </tag>
    <tag>
  some visible data
    </tag>
</root>

produces the wanted, correct result:

<div id="page-base">
   <form>
   some html form will be here
        </form>
</div>
<div id="page-base">
  some visible data
    </div>

Explanation:

Your code lacked something to copy the body of the matched tag element.

This “something” is the xsl:copy-of instruction.

---

Update:

The OP has changed his question and this requires a different solution:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/*"><xsl:apply-templates/></xsl:template>

 <xsl:template match="tag">
  <div id="page-base">
    <xsl:apply-templates/>
  </div>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the newly-provided XML document:

<div id="page-base">
   <form>
           some html form will be here
          </form>
   <div id="page-base">
            arbitrary nested tags
          </div>
</div>
<div id="page-base">
          some visible data
        </div>