Question

Say I have a class in Coffeescript:

class MyGame
   constructor: () ->
      @me = new Player
      @opponents = [new Player, new Player]

which would like to test in Jasmine:

describe "MyGame", ->
   beforeEach ->
     window.game = new MyGame

   it "should have two players", ->
      expect(window.game.opponents.length).toEqual 2

But I get the error TypeError: Result of expression 'window.game.opponents' [undefined] is not an object.?

The window.game approach also seem awkward to me. If I try to define it as @game = new MyGame I get the error ReferenceError: Can't find variable: MyGame but I guess that has something to do with the way Coffeescript is wrapping things up?

UPDATE: The problem seems more like a reference problem as described above. I’m running with guard-jasmine which looks like

guard 'jasmine', :all_on_start => false, :all_after_pass => false do
  watch(%r{app/assets/javascripts/(.+)\.(js\.coffee|js)}) { |m| "spec/javascripts/#{m[1]}_spec.#{m[2]}" }
  watch(%r{spec/javascripts/(.+)_spec\.(js\.coffee|js)})  { |m| "spec/javascripts/#{m[1]}_spec.#{m[2]}" }
  watch(%r{spec/javascripts/spec\.(js\.coffee|js)})       { "spec/javascripts" }
end

and my jasmine.yml file has:

src_files:
    - "app/assets/**/*.js"
    - "app/assets/**/*.coffee"
spec_files: 
    - '**/*[sS]pec.js.coffee' 
asset_pipeline_paths: 
    - app/assets 
    - spec/javascripts

I get the an ReferenceError: Can't find variable: MyGame so I figure it’s either something with the Rails 3.1 asset pipeline or the way Coffeescript wraps objects.

Answer 1

try defining your coffeescript class using the @ operator as such:

class @MyGame
   constructor: () ->
      @me = new Player
      @opponents = [new Player, new Player]

this will allow you to access the class from anywhere, such as from your jasmine tests, and also you can get away from attaching testing variables to window:

describe "MyGame", ->
   beforeEach ->
     @game = new MyGame

   it "should have two players", ->
      expect(@game.opponents.length).toEqual 2

the reason for this is that coffeescript goes out of its way to avoid introducing global variables by wrapping everything in a closure. unfortunately, this can be undesirable for object-oriented code. using the @ operator attaches the class definition to the global this, which is window, and thus allows you to instantiate your classes as you like. you may have some global vars in your global space now, your classes, but for me its an ok trade-off. hope this helps!