Question

Scroller can be added to Richeditabletext in mxml.

<s:BorderContainer>
    <s:Scroller width="335" height="265" >
        <s:RichEditableText backgroundColor="0x900000"  id='_text'  color="0x000000" width="335" height="265"   text="Hellooooo"/>  
    </s:Scroller>
</s:BorderContainer>

But the same implemented in Actionscript throws Argument Error

ArgumentError: This operation is not supported.
at spark.components::Scroller/addElement()[E:\dev\4.y\frameworks\projects\spark\src\spark\components\Scroller.as:2277]

Actionscript code by which throws error

var bc:BorderContainer = new BorderContainer();
var scroller:Scroller = new Scroller();
var richEditableText:RichEditableText = new RichEditableText();
scroller.addElement(richEditableText);
bc.addElement(richEditableText);
changedTextComponent.addElement(bc);

Thanks in advance..

Answer 1

Hi Below code may help you: –

instead of scroller.addElement(richEditableText); replace scrollRTE.viewport = richEditableText and the problem is solved…

BorderContainerClass.as

package
{
    import spark.components.BorderContainer;
    import spark.components.RichEditableText;
    import spark.components.Scroller;

    public class BorderContainerClass extends BorderContainer
    {
        public function BorderContainerClass()
        {
            super();
        }

        private var scrollRTE:Scroller;
        private var richEditableText:RichEditableText;

        override protected function createChildren():void
        {
            if(!scrollRTE)
            {
                scrollRTE = new Scroller();
                scrollRTE.width = 335; 
                scrollRTE.height = 265;
            }
            if(!richEditableText)
            {
                richEditableText = new RichEditableText();
            }
            richEditableText.setStyle('backgroundColor','0x900000');  
            richEditableText.setStyle('color','0x000000');  
            richEditableText.width = 335;
            richEditableText.height= 265;   
            richEditableText.text="Hellooooo";
            scrollRTE.viewport = richEditableText
            this.addElement(scrollRTE);
        }
    }
}