Question

So I have created my vdeo player , but Im havin problems handling different sized videos. How to properly scale videos proportionally?

I get original width and height from metadata object:

        private function onMetaData(newMeta:Object):void
        {           
            _height = newMeta.height;
            _width = newMeta.width;
            scaleProportional();
        }

Answer 1

1. Proportional factor

One way to do this is to calculate the proportional factor. It is equal to the width divided by the height:

var proportions: Number = video.width / video.height;

You can apply that factor to any new width or height you set the video to:

function scaleProportionalByWidth ( newWidth:Number ) : void {
    video.width = newWidth;
    video.height = newWidth / proportions;
}

function scaleProportionalByHeight ( newHeight : Number ) : void {
    video.height = newHeight;
    video.width = newHeight * proportions;
}

2. Scaling factor

Another way to do it is to find out by which factor to scale the video, then set scaleX and scaleY instead of width and height:

function scaleProportionalByWidth ( newWidth : Number ) : void {
    scaleProportional ( newWidth, video.width );
}

function scaleProportionalByHeight ( newHeight : Number ) : void {
    scaleProportional ( newHeight, video.height );
}

function scaleProportional ( newValue:Number, oldValue : Number ) : void {
    var scale:Number = newValue / oldValue;
    video.scaleX *= scale;
    video.scaleY *= scale;
}

3. Proportional display object classes

You can also use the approach in 2. to create a proportional subclass of any DisplayObject by overriding the setters for width, height, scaleXand scaleY to make all scaling proportional:

                                           //  works for Sprite, MovieClip...
public class ProportionalDisplayObject extends DisplayObject { 
    override public function set width ( width:Number ) : void {
        scaleX = width / super.width;
    }

    override public function set height ( height:Number ) : void {
        scaleY = height / super.height;
    }

    override public function set scaleX ( scaleX : Number ) : void {
        super.scaleX = super.scaleY = scaleX;
    }

    override public function set scaleY ( scaleY : Number ) : void {
        super.scaleY = super.scaleX = scaleY;
    }
}