Question

So I have many objects with materials that each possess different properties (brick, glass, etc.) and are each affected differently by elemental effects. A brick material for example will be affected differently by fire or acid than a cement material. A brick that’s Burning or Melting will be affected differently when another Burning/Melting effect is applied.

At this point in my game, I have an FSM but it’s very simple. If I drop a fire element on a brick, it would go to the Burning state. However if I then dropped a water element on the brick, I might want the fire to go out, take/add health and change textures (or not depending on the current combination).

The point is, I have many combinations with no commonality between them so I can’t create something uniform. Sometimes I need to change the texture and other times I don’t. Sometimes take damage while other times add health. Sometimes I need to just do nothing in a function. At this point, the only thing I can thing of is creating a global mapping such as:

FunctionMap[ObjectMaterial][CurrentObjectState][ElementBeingApplied]

(i.e.

FunctionMap[Brick][Burning][Acid]
FunctionMap[Brick][Melting][Acid]

)

The problem is, is that this is obviously a ton of functions due to the amount of combinations available with materials and effect types. Can anyone recommend a route to take or pattern to look at?

Although not entirely relevant to the discussion, this is being made in AS3 and Away3D.

Here are some of my classes for one example:

public class Brick extends AbstractBlock implements IFireable
{
    public function Brick()
    {
        super(this);
        this.material = new BitmapMaterial(_spriteManager.GetBlockMaterial(BlockUtilities.GetMaterialMap["brick_new"]));
        _type = "Brick";
        /*
        RulesManager.StateMap["Brick"]["OnFire"]["Water"] = some function;
        RulesManager.StateMap["Brick"]["OnFire"]["Fire"] = some function;
        RulesManager.StateMap["Brick"]["OnFire"]["Acid"] = some function;
        RulesManager.StateMap["Brick"]["OnFire"]["Ice"] = some function;
        RulesManager.StateMap["Brick"]["OnWater"]["Water"] = some function;
        //and so on...there are nine different materials so I'm not liking this way
        */
    }

    public override function render():void
    {
        super.render();
    }
}   


public class OnFire extends AbstractDamage
{       

    protected var _timeStart:Number = 0;

    private var _damageAccumulated:Number = 0;

    public function OnFire(block:AbstractBlock,bombType:String) 
    {       
        super(block,bombType);                                      
    }

    public override function enter():void        
    {       
        super.enter();  
    }

    public override function exit():void         
    {       
        super.exit();                                       
    }

    public override function update(time:Number):void
    {
        super.update(time);

        if(_timeStart == 0)
            _timeStart = time;

        var time_delta:Number = (time - _timeStart)/_waitTime;

        var damageToSubtract:Number = (time_delta * _damageDone);

        _damageAccumulated += damageToSubtract;

        _self.Integrity = _self.Integrity - _damageAccumulated;


    }
}

}

Thus, a fire element could be applied to a bunch of applies. One those blocks, currently frozen, is now hit and is now changing to the OnFire state. Each block has its own state machine and the states are themselves objects as you can see.

block.FSM.changeState(new OnFire(block));

Answer 1

So your problem is that you have 9 * 5 * 4 combinations of effects, right? Having separate functions for each of those would not be fun to manage. But, even if it’s a lot of data, you need it. I would make that data as simple as possible, then parse it. Something like:

var materialProperties = {
  brick: {
    fire: {
      normal: {damage: 10, image: 'brick_fire.jpg'},
    }
    water: {
      fire: {damage: 0, image: 'brick_smoking.jpg'}
    }
  },
  //... a lot more of this ...
}

class Material
{
  public var damage:int = 0;
  public var image:String = '';

  private var properties:Object;
  private var state:String;

  public function Material(properties)
  {
    this.properties = properties;
  }

  public function apply(effect:String):void
  {
    if(properties[effect])
    {
      if(properties[effect][state])
      {
        update(properties[effect][state]);
      }
      else if(properties[effect]['normal'])
      {
        update(properties[effect]['normal']);
      }
    }
    state = effect;
  }

  private function update(properties):void
  {
    damage += properties.damage;
    image = properties.image;
  }
}

var brick = new Material(materialProperties.brick);
brick.apply('fire');
brick.apply('water');