Question

So I have this calculator I’m building that accepts user variable inputs like “let a = 2” These variable are stored in a List of Tuples (Variable, value) I need help with getting the data from this list. My code so far

primary :: Parser Float
primary = do symbol "("
         e <- expression
         symbol ")"
         return e
       +++ do v <- identifier                 
              let a = (find (==(head v)) vlist)
              return a

I get an error because find returns a Maybe and I need it to return a Float or give the user an error message. How do I do this?

Answer 1

I’m not sure where vlist comes from. It should probably be part of the parser’s user state. For now, let’s assume it’s a top-level definition:

vlist :: [(String, Float)]
vlist = undefined -- fill in the blanks...

I assume you’re using Parsec. You can simplify your parser to:

primary :: Parser Float
primary = choice [ between (symbol "(") (symbol ")") expression
                 , do { ident <- identifier
                      ; case lookup ident vlist of
                          Nothing -> fail $ "No such identifier: " ++ ident
                          Just v -> return v
                      }
                 ]

You have several options for how to deal with the error. Here, I have used the parser monad’s fail function. This will cause the parser to return a Left parserError. Alternatively, you could substitute error for fail, which will result in an error that can only be handled in the IO monad.

Note: To add the vlist as parser state, you need to define a new parser type with that state:

data MyParserState = MyParserState { vlist :: [(String, Float)] }
type MyParser = CharParser MyParserState

-- these parsers now need to return MyParser type!
symbol :: String -> MyParser String
identifier :: MyParser String
expression :: MyParser Float

primary :: MyParser Float
primary = choice [ between (symbol "(") (symbol ")") expression
                 , do { st <- getState
                      ; ident <- identifier
                      ; case lookup ident $ vlist st of
                          Nothing -> fail $ "No such identifier: " ++ ident
                          Just v -> return v
                      }
                 ]