Question

So, I’m trying to get some XML into an easy format for dumping into a DB. This is what it looks like:

<?xml version="1.0" encoding="UTF-8"?>
<detail type="Courses Taken" gm_recid="FNBYHVW(,7()E)S" >
          <properties>
            <property name="reference" >
              <property_string>M2</property_string>
            </property>
            <property name="Month YYYY" db_name="TITLE" >
              <property_string></property_string>
            </property>
            <property name="City, State" db_name="LINKACCT" >
              <property_string></property_string>
            </property>
          </properties>
</detail>

which I’d prefer looked like:

<?xml version="1.0" encoding="UTF-8"?>
<courses_taken>
    <gm_recid>FNBYHVW(,7()E)S</gm_recid>
    <reference>M2</reference>
    <date></date>
    <location></location>
</courses_taken>

I’m not too familiar with XSL, so I’m at a loss for where to start. Can someone point me in the right direction?

Answer 1

This complete XSLT transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vUpper" select=
 "'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

 <xsl:variable name="vLower" select=
 "'abcdefghijklmnopqrstuvwxyz'"/>

 <xsl:variable name="vDigits" select=
 "'0123456789'"/>

 <xsl:variable name="vAlphaNum" select=
  "concat($vUpper, $vLower, $vDigits, '_')"/>

 <xsl:template match="detail">
  <xsl:element name=
  "{translate(@type,
              translate(@type, $vAlphaNum, ''),
              '______________________________'
              )}">
   <xsl:apply-templates select=
     "@*[not(name()='type')]|*"/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="detail/@*">
  <xsl:element name=
  "{translate(name(),
              translate(name(), $vAlphaNum, ''),
              '______________________________'
              )}">

   <xsl:value-of select="."/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="property[@name='reference']">
  <reference>
   <xsl:value-of select="."/>
  </reference>
 </xsl:template>

 <xsl:template match="property[@name='Month YYYY']">
  <date>
   <xsl:value-of select="."/>
  </date>
 </xsl:template>

 <xsl:template match="property[@name='City, State']">
  <location>
   <xsl:value-of select="."/>
  </location>
 </xsl:template>
</xsl:stylesheet>

when applied on the provided XML document:

<detail type="Courses Taken" gm_recid="FNBYHVW(,7()E)S" >
          <properties>
            <property name="reference" >
              <property_string>M2</property_string>
            </property>
            <property name="Month YYYY" db_name="TITLE" >
              <property_string></property_string>
            </property>
            <property name="City, State" db_name="LINKACCT" >
              <property_string></property_string>
            </property>
          </properties>
</detail>

produces the wanted, correct result:

<Courses_Taken>
   <gm_recid>FNBYHVW(,7()E)S</gm_recid>
   <reference>M2</reference>
   <date/>
   <location/>
</Courses_Taken>

Explanation: Using a variation of the double-translate method first proposed by @Michael Kay:

If we have a string $s and a string of only allowable characters $valid and we want to get from $s another string $s2 which contains only the valid character of $s (in their original order), this can be achieved by evaluating the following XPath expression:

translate($s, translate($s, $valid, ''), '')

In this particular case we want not to delete the invalid characters, but to replace each of them with "_".

We assume that a candidate name will not exceed the length of 30 and use a fixed-length replacement string (this of course can be made as large as wanted):

translate($s, 
          translate($s, $valid, ''), 
         '______________________________')