Question

So I’ve created a simple Macro to:

• un-hide a worksheet.
• find and replace text.
• re-hide the worksheet.

I have this macro working, but can only get it to work when I embed the macro code into a worksheet.

Here is the code;

Sub UpdateChartParams()

Dim Chart_Parameters As Worksheet

Sheets("Chart_Parameters").Visible = True

Sheets("Chart_Parameters").Select
Cells.Replace What:="testtext", Replacement:="newtext", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False

Sheets("Chart_Parameters").Visible = False

End Sub

What I need to do is run this file against any open workbooks if possible.

Answer 1

This will update any open workbook(s) with a matching sheet.
No need to unhide to run the replace.

Sub UpdateChartParams()

    Dim Chart_Parameters As Worksheet
    Dim wb As Excel.Workbook

    For Each wb In Application.Workbooks
    If wb.Name <> ThisWorkbook.Name Then

        Set Chart_Parameters = Nothing
        On Error Resume Next 'ignore error if no such sheet...
        Set Chart_Parameters = wb.Worksheets("Chart_Parameters")
        On Error GoTo 0

        If Not Chart_Parameters Is Nothing Then

            Chart_Parameters.Cells.Replace What:="testtext", _
                   Replacement:="newtext", LookAt:=xlPart, _
                    SearchOrder:=xlByRows, MatchCase:=False

        End If

    End If
    Next wb

End Sub