Question

So to make this simple. I have Cells A,B,C,D

Cell D = B-C

B is basically apples won, and C is apples lost for explanation purposes. D is net apples.

I want to make it so that I can enter a number of apples won into cell A, and then it will add that number into Cell B, then clear the A or allow me to clear it while retaining Cell B value of B+A.

Thank you

Answer 1

Only with code

If you:

• right click you sheet tab
• View Code
• copy and paste the code below

Then cells B1 to B5 will keep a running total of all the corresponding values in A1 to A5. Change this line Set rng1 = Intersect(Target, Range("A1:A5")) to set the range which the code works on (running totals are added to the immediate right)

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rng1 As Range
    Dim rng2 As Range
    Set rng1 = Intersect(Target, Range("A1:A5"))
    If rng1 Is Nothing Then Exit Sub
    Application.EnableEvents = False
    For Each rng2 In rng1.Cells
        rng2.Offset(0, 1).Value = rng2.Offset(0, 1).Value + rng2.Value
    Next
    Application.EnableEvents = True
End Sub

[updated – for your additional query you could try this]

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rng1 As Range
    Dim rng2 As Range
    Application.EnableEvents = False
    Set rng1 = Intersect(Target, Range("A1:A5"))
    If Not rng1 Is Nothing Then Call UpdateCells(rng1, 1)
    Set rng1 = Intersect(Target, Range("D1:D5"))
    If Not rng1 Is Nothing Then Call UpdateCells(rng1, 2)
    Application.EnableEvents = True
End Sub


Sub UpdateCells(ByVal rng1, lngCol As Long)
    Dim rng2 As Range
    For Each rng2 In rng1.Cells
        rng2.Offset(0, lngCol).Value = rng2.Offset(0, lngCol).Value + rng2.Value
    Next
End Sub