Question

Sorry but a total xslt noob here

Given XML that looks like:

<Foo>
  <Bar />
  <Baz />
  <Qax />
  <FooBar />
</Foo>

Is there an XSLT that will limit the number of child nodes under Foo so that there are only 3?

Answer 1

This transformation uses and overrides the identity rule/template:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/*/*[position() > 3]"/>
</xsl:stylesheet>

When applied on the provided XML document:

<Foo>
    <Bar />
    <Baz />
    <Qax />
    <FooBar />
</Foo>

the wanted, correct result is produced:

<Foo>
   <Bar/>
   <Baz/>
   <Qax/>
</Foo>

Explanation:

1. The identity rule/template copies every node “as-is”.

2. We have just one additional template that overrides the identity rule for any element that is a child of the top element with position greater than 3. This template dos nothing (has an empty body), which effectively prevents any such element from being copied to the output (or as we use to say, “deletes” it).

Do note:

1. Using and overriding the identity rule is the most fundamental and powerful XSLT design pattern.

2. Using this design pattern is recommended over a simple <xsl:copy-of>, because it allows the nodes not only to be copied, but to be processed by any template we provide. Attributes of all elements are also processed.