Question

Sorry for the bad title but this is the best I could do! 😀

I have a script which creates a new project every time the specified function is called.

Each project must be stored in its own folder, with the name of the project. But, if you don’t specify a name, the script will just name it “new projectX”, where X is a progressive number.

With time the user could rename the folders or delete some, so every time the script runs, it checks for the smallest number available (not used by another folder) and creates the relevant folder.

Now I managed to make a program which I think works as wanted, but I would like to hear from you if it’s OK or there’s something wrong which I’m unable to spot, given my inexperience with the language.

    while ( defined( $file = readdir $projects_dir ) )
    {
        # check for files whose name start with "new project"
        if ( $file =~ m/^new project/i )
        {
            push( @files, $file );
        }
    }

    # remove letters from filenames, only the number is left
    foreach $file ( @files )
    {
        $file =~ s/[a-z]//ig;
    }

    @files = sort { $a <=> $b } @files;

    # find the smallest number available
    my $smallest_number = 0;

    foreach $file ( @files )
    {
        if ( $smallest_number != $file )
        {
            last;
        }
        $smallest_number += 1;
    }

    print "Smallest number is $smallest_number";

Answer 1

I think I would use something like:

use strict;
use warnings;

sub new_project_dir
{
    my($base) = @_;
    opendir(my $dh, $base) || die "Failed to open directory $base for reading";
    my $file;
    my @numbers;
    while ($file = readdir $dh)
    {
        $numbers[$1] = 1 if ($file =~ m/^new project(\d+)$/)
    }
    closedir($dh) || die "Failed to close directory $base";
    my $i;
    my $max = $#numbers;
    for ($i = 0; $i < $max; $i++)
    {
        next if (defined $numbers[$i]);
        # Directory did not exist when we scanned the directory
        # But maybe it was created since then!
        my $dir = "new project$i";
        next unless mkdir "$base/$dir";
        return $dir;
    }
    # All numbers from 0..$max were in use...so try adding new numbers...
    while ($i < $max + 100)
    {
        my $dir = "new project$i";
        $i++;
        next unless mkdir "$base/$dir";
        return $dir;
    }
    # Still failed - give in...
    die "Something is amiss - all directories 0..$i in use?";
}

Test code:

my $basedir = "base";
mkdir $basedir unless -d $basedir;

for (my $j = 0; $j < 10; $j++)
{
    my $dir = new_project_dir($basedir);
    print "Create: $dir\n";
    if ($j % 3 == 2)
    {
        my $k = int($j / 2);
        my $o = "new project$k";
        rmdir "$basedir/$o";
        print "Remove: $o\n";
    }
}