Question

Sorry the title is not very descriptive but it is a tricky problem to word.

I have some data, about 200 or more rows of it, and each row has a PacketID, so several rows belong in the same packet. What I need to do, is convert all the PacketIDs from (Example – BDFD-2) to just a number (Example – 1) so all the entries with a packet identifier x need to have a packet identifier of say 3. Is there an SQL query that can do this? Or do I just have to go through manually.

Answer 1

You asked about a query. I wrote a quick VBA procedure instead just because it was so easy. But I’m unsure whether it is appropriate for your situation.

I created tblPackets with a numeric column for new_PacketID. I hoped that will make it clearer to see what’s going on. If you truly need to replace PacketID with the new number, you can alter the procedure to store CStr(lngPacketID) to that text field. So this is the sample data I started with:

PacketID new_PacketID packet_data
BDFD-2                a
R2D2-22               aa
BDFD-2                b
R2D2-22               bb
EMC2-0                aaa
EMC2-0                bbb

And this is the table after running the procedure.

PacketID new_PacketID packet_data
BDFD-2              1 a
R2D2-22             3 aa
BDFD-2              1 b
R2D2-22             3 bb
EMC2-0              2 aaa
EMC2-0              2 bbb

And the code …

Public Sub RenumberPacketIDs()
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim lngPacketID As Long
    Dim strLastPacketID As String
    Dim strSql As String

    strSql = "SELECT PacketID, new_PacketID" & vbCrLf & _
        "FROM tblPackets" & vbCrLf & _
        "ORDER BY PacketID;"
    Set db = CurrentDb
    Set rs = db.OpenRecordset(strSql)

    With rs
        Do While Not .EOF
            If !PacketID <> strLastPacketID Then
                lngPacketID = lngPacketID + 1
                strLastPacketID = !PacketID
            End If
            .Edit
            !new_PacketID = lngPacketID
            .Update
            .MoveNext
        Loop
        .Close
    End With

    Set rs = Nothing
    Set db = Nothing
End Sub

I think an approach like that could be fine for a one-time conversion. However if this is an operation you need to perform repeatedly, it could be more complicated … especially if you need each PacketID replaced with the same number from one run to the next … eg. BDFD-2 was replaced by 1 the first time, so must be replaced by 1 every time you run the procedure.