Question

Summary: I’m looping through many rows of data and storing data from different columns in about 6 different variables each time through the loop

Question: Would I save a very significant amount of CPU cycles using Range("A" & some iterator) as opposed to ActiveCell.Offset(some number)? How much quicker is one than the other?

Thanks in advance!

Answer 1

Out of sheer boredom and a little curiosity I put together a crude timer for various methods to cycle 100,000 Excel cells.

Ideally you should run each a number of times and take the average but it gives you a rough outline of speed.

On my machine this is what I get

Option Explicit

#If Win64 Then
    Public Declare PtrSafe Function GetTickCount Lib "kernel32" () As Long
#Else
    Public Declare Function GetTickCount Lib "kernel32" () As Long
#End If

Sub TestSpeedofReadingCells()
Dim tcStart As Long
Dim tcEnd As Long
Dim temp As Variant

Dim i As Long
Dim rngobject As Range
Dim rngItem As Range
Dim rngArray() As Variant
Const rowsToRead As Long = 100000


    '***Read individual cells using .Range
    With Sheet1
        tcStart = GetTickCount
        For i = 1 To rowsToRead
            temp = .Range("A" & i).Value
        Next i
        tcEnd = GetTickCount
        Debug.Print "Time1: " & tcEnd - tcStart
    End With

    '***Read individual cells using .Range & screenupdating off
    With Sheet1
        Application.ScreenUpdating = False
        tcStart = GetTickCount
        For i = 1 To rowsToRead
            temp = .Range("A" & i).Value
        Next i
        tcEnd = GetTickCount
        Application.ScreenUpdating = True
        Debug.Print "Time1a: " & tcEnd - tcStart
    End With

    '***Read individual cells using .Range & screenupdating off & using value2
    With Sheet1
        Application.ScreenUpdating = False
        tcStart = GetTickCount
        For i = 1 To rowsToRead
            temp = .Range("A" & i).Value2
        Next i
        tcEnd = GetTickCount
        Application.ScreenUpdating = True
        Debug.Print "Time1b: " & tcEnd - tcStart
    End With

    '***Read individual cells using range object
    With Sheet1
        Set rngobject = .Range("A1:A" & rowsToRead)
        tcStart = GetTickCount
        For Each rngItem In rngobject
            temp = rngItem
        Next rngItem
        tcEnd = GetTickCount
        Debug.Print "Time2: " & tcEnd - tcStart
    End With

    '***Read individual cells using activecell
    With Sheet1
        tcStart = GetTickCount
        .Range("A1").Select
        For i = 1 To rowsToRead
            temp = ActiveCell.Offset(i - 1, 0).Value
        Next i
        tcEnd = GetTickCount
        Debug.Print "Time3: " & tcEnd - tcStart
    End With

    '***Read individual cells using activecell & screenupdating off
    With Sheet1
        Application.ScreenUpdating = False
        tcStart = GetTickCount
        .Range("A1").Select
        For i = 1 To rowsToRead
            temp = ActiveCell.Offset(i - 1, 0).Value
        Next i
        tcEnd = GetTickCount
        Application.ScreenUpdating = True
        Debug.Print "Time3a: " & tcEnd - tcStart
    End With

    '***Read individual cells using array
    With Sheet1
        tcStart = GetTickCount
        rngArray = .Range("A1:A" & rowsToRead).Value
        For i = 1 To rowsToRead 'should really use Lbound to Ubound but only example
            temp = rngArray(i, 1)
        Next i
        tcEnd = GetTickCount
        Debug.Print "Time4: " & tcEnd - tcStart
    End With

End Sub