Question

Suppose I have a configuration file that can be in one of two format below (short example, but basically the first format is a line that is too long that you have to use a line continuation character, while the second format is just simply a long line without the line continuation)

data1=x data2=y data3=z \
datakey

second format

data=1 data2=y data3=z datakey

I want to match the exact line data1=x data2=y data3=x datakey for both situation. Is there simple way of doing that?

Answer 1

I would use sed to create an output without the ending \:

sed -e ':begin;/\\$/{N;bbegin};s/\\\n//g' your_file

Then you could grep it:

sed -e ':begin;/\\$/{N;bbegin};s/\\\n//g' your_file | grep your_pattern

You can even do this all in sed:

sed -n -e ':begin;/\\$/{N;bbegin};s/\\\n//g;/your_pattern/p' your_file

UPDATE:

To explain above:

• :begin sets a tag to which I can branch (goto) with the b command.
• /\\$/{N;bbegin} if the current line ends with a \ (/\\$/), append the next line to the buffer (N) and goto begin (bbegin).
• Then, when the lines does not end with a \, remove all the \ and the line break (thes/\\n//g`).
• Then -n option tells sed no to print the line at the end of the script.
• /your_pattern/p prints the line if it matches your_pattern.

UPDATE2:

We could even do better and show the original lines of your file:

sed -n -e ':begin;/\\$/{N;bbegin};h;s/\\\n//g;/your_pattern/{g;p}' your_file

What this does is before removing the \ and the line break, it saves the data in the hold space (h) and if the line matches, it prints the data that was saved (g copies the hold space to the pattern space that is printed).