Question

$test='abc="def"';
$replacement='$1="ghj"';
$test =~ s/(.+)="(.+)"/"$replacement/;
print $test;

It prints:

$1=ghj

How can I treat $replacement to be interpreted?

Answer 1

There are approximately 3 answers to this question.

• Your replacement “string” is actually code to be evaluated at match time to generate the replacement string. That is, it is better represented as a function:

my $test = 'abc="def"';
my $replacement = sub { $1 . '="ghj"' };
$test =~ s/(.+)="(.+)"/$replacement->()/e;
print $test;

• If you don’t need the full power of arbitrary Perl expressions (or if your replacement string comes from an external source), you can also treat it as a template to be filled in with the match results. There is a module that encapsulates this in the form of a JavaScript-like replace function, Data::Munge:

use Data::Munge qw(replace);
my $test = 'abc="def"';
my $replacement = '$1="ghj"';
$test = replace $test, qr/(.+)="(.+)"/, $replacement;
print $test;

• Finally, you can represent Perl code as a string to be eval‘d. This is not only inefficient but also fraught with quoting issues (you have to make sure everything in $replacement is syntactically valid Perl) and security holes (if $replacement is generated at runtime, especially if it comes from an external source). My least favorite approach:

my $test = 'abc="def"';
my $replacement = '$1 . "=\\"ghj\\""';
$test =~ s/(.+)="(.+)"/eval $replacement/e;
print $test;

(The s//eval $foo/e part can also be written as s//$foo/ee. I don’t like to do that because eval is evil and shouldn’t be more hidden than it already is.)