Question

the code below returns the fields of a given table (“Employee”), but I need to return the fields of ALL the tables in the given database, is this possible? My assumption is a For loop which loops round the tables in the database and prints the corresponding fields but my efforts seem to be in vain

Public Sub getDbFields()

    Dim i As Integer
    Dim dbcon As New System.Data.OleDb.OleDbConnection("PROVIDER=Microsoft.Jet.OLEDB.4.0;Data Source = " & dblocation & _
                                               "\" & dbname)
    Try

        dbcon.Open()
        dbDt = dbcon.GetOleDbSchemaTable(OleDb.OleDbSchemaGuid.Columns, New Object() _
                                         {Nothing, Nothing, "Employee", Nothing})

        For i = 0 To dbDt.Rows.Count - 1
            'compile lbtables with a list of available tables from the database
            newLine()
            frmMain.lstTables.Items.Add(dbDt.Rows(i)!COLUMN_NAME.ToString())
        Next

    Catch ex As Exception
        MessageBox.Show(ex.Message.ToString(), "Data Load Error", MessageBoxButtons.OK,
            MessageBoxIcon.Exclamation)
    End Try

End Sub

This routine will be fired from the selection of a checkbox

Answer 1

This will return all columns on a database

Using con = new OleDbConnection("Provider=Microsoft.ACE.OLEDB.12.0;" + 
                          "Data Source=" + dblocation + "\" + dbname)
    con.Open()
    Dim schema as DataTable = con.GetSchema("COLUMNS")
    Dim dr as DataRow
    For Each dr in schema.Rows
        Dim tablename as string = dr("TABLE_NAME").ToString()    
        if Not tablename.StartsWith("MSys") then
            Console.WriteLine(dr("TABLE_NAME").ToString() + " " + dr("COLUMN_NAME").ToString())
        End if        
    Next    
End Using

Please note that the bang (!) syntax is not allowed in vb.net.
Also your code could work if you change

 dbDt = dbcon.GetOleDbSchemaTable(OleDb.OleDbSchemaGuid.Columns, New Object() _ 
                                          {Nothing, Nothing, Nothing, Nothing}) 

and this line

frmMain.lstTables.Items.Add(dbDt.Rows(i)("COLUMN_NAME").ToString())