Question

The following code returns 14 as you’d expect:

Block[{expr},
  expr = 2 z;
  f[z_] = expr;
  f[7]]

But if you change that Block to a Module then it returns 2*z.
It seems to not matter what other variables besides expr you localize.
I thought I understood Module, Block, and With in Mathematica but I can’t explain the difference in behavior between Module and Block in this example.

Related resources:

• Tutorial on Modularity and the Naming of Things from the Mathematica documentation
• Excerpt from a book by Paul R. Wellin, Richard J. Gaylord, and Samuel N. Kamin
• Explanation from Dave Withoff on the Mathematica newsgroup

PS: Thanks to Michael Pilat, Davorak, and Bill White for following the scent-trail on this weirdness.
Davorak clarifies and gets to the heart of the issue here:
Why would Mathematica break normal scoping rules in Module?

Answer 1

I too was a bit surprised by this, but I don’t think it’s a bug. If you look deep in the examples in the reference page for Module, under the section labeled Possible Issues, there’s a little note that says “Variables are renamed in nested scopes” and gives the following example:

In[1]:= Module[{e = Expand[(1 + x)^5]}, Function[x, e]]

Out[1]= Function[x$, e$1194]

In[2]:= %[10]

Out[2]= 1 + 5 x + 10 x^2 + 10 x^3 + 5 x^4 + x^5 

Function is another scoping construct like Module, so x is renamed internally to x$ in the scope of the Function, similar to what you discovered with Trace about z.

In your Module defining f, Set is another such scoping construct, and therefore z is renamed when f is defined inside of a Module, but not when it’s inside a Block. Following the advice of that example from the Module documentation, you can build the RHS of your function from its parts to avoid the lexical renaming of the nested scope:

In[3]:= Clear[f, z]

In[4]:= Module[{expr},
  expr = 2 z;
  Set @@ {f[z_], expr};
  f[7]]

Out[4]= 14

HTH!