Question

the perl code is like followed : the problem is that I can not read $key inside sub tweak_server{} ….

my $key;
my %hash = ( flintstones => [ "C:/Users1/f1.xml", "C:/Users1/f2.xml" ], 
            jetsons => [ "C:/Users2/f1.xml" ], 
            simpsons =>    [ "C:/Users3/f1.xml", "C:/Users3/f1.xml", "C:/Users3/f1.xml" ], ); 

foreach $key (keys%hash){
if (scalar@{$hash{$key}}>1){
    foreach my $path (@{$hash{$key}}){
        my $filehandle;
        open($filehandle, "+<$path") or die "cannot open out file out_file:$!";
        my $roots = { TAG => 1 };
        my $handlers = { 'ROOT/TAG' => \&tweak_server,
                    };
        my $twig = new XML::Twig(TwigRoots => $roots,
                             TwigHandlers => $handlers,
                             twig_print_outside_roots => \*$filehandle);
        $twig->parsefile($path);
        say $key;#could read key
        sub tweak_server {
            my ($twig, $root) = @_;
            my $tag2=$root->first_child_text('TAG2'); 
            say $key;# could not read
            if ($tag2=~/$key/){
            #BLABLA
            }
            $twig->flush( $filehandle, pretty_print => 'indented');
        }
    }
}

}

as i state, the $key can be read outside the sub, but not inside..the error appeared:Use of uninitialized value $key

and then i tried a simple situation, just like

my $a="aaa";
open( $filehandle, "+<$path") or die "cannot open out file out_file:$!";
my $roots = { TAG => 1 };
my $handlers = { 'ROOT/TAG' => \&tweak_server,
            };
my $twig = new XML::Twig(TwigRoots => $roots,
                     TwigHandlers => $handlers,
                     twig_print_outside_roots => \*$filehandle
                     );
$twig->parsefile($path);
sub tweak_server {
    say $a;
    my ($twig, $root) = @_;
    my $tags=$root->first_child_text('TAG2');
    my $str="204B";
    if ($tag2=~m/$str/){
    foreach my $b(1...6){
                    say $a;             }
}
$twig->flush( $filehandle, pretty_print => 'indented');

}

in this code, the $a can be read….
i spent one day on this, but still can’t fix it…crazy now
thank in advance!!

Answer 1

You are declaring $key outside of the for loop. Then, inside the for loop, you define a subroutine that closes on $key.

As a general rule, declare variables in the smallest applicable scope. For example:

for my $key (keys ...) {

or

open my $filehandle, '<', ...

Why are you defining sub tweak_server in the body of the for loop? It seems to me, what you want to do is to define a new anonymous sub for each iterationn.

First, a short example that replicates what you are observing:

use warnings; use strict;

my $key;
my %hash = qw(a b c d e f);

foreach $key (keys %hash) {
    somesub();
    sub somesub {
        print "$key\n";
    }
}

Now, the fix:

use warnings; use strict;

my %hash = qw(a b c d e f);

foreach my $key (keys %hash) {
    my $somesub = sub { print "$key\n" };
    $somesub->();
}

This way, we define a new anonymous function at each iteration and each new sub closes over each value of the loop variable.

In terms of your code, you should then replace the named sub with

my $tweak_server = sub {
    my ($twig, $root) = @_;
    my $tag2=$root->first_child_text('TAG2'); 
    say $key;# could not read
    if ($tag2=~/$key/){
        #BLABLA
    }
    $twig->flush( $filehandle, pretty_print => 'indented');
}

my $handlers = { 
    'ROOT/TAG' => $tweak_server,
};

Or, even better, as @mirod observes, pass $key to tweak_server:

sub tweak_server { 
    my( $key, $twig, $root)= @_;
    ...
}

And, in the body of the loop,

my $handlers = { 
    'ROOT/TAG' => sub { tweak_server($key, @_) },
};