Question

There are two lists of dates (no assumptions can be made regarding list order)

//first list
[date_a; date_b; date_c]
//second list
[date_A; date_B; date_C]

I am looking for a function that returns the following as a list of entries:
the date is unique key (a single date will appear only once in the list)

-> (date, true, true) in case both lists contained the date
-> (date, true, false) in case the first list contained the date
-> (date, false, true) in case the second list contained the date
(there will be no (date, false, false) entries)

Answer 1

Using some simple set operations:

open System

//'a list -> 'a list -> ('a * bool * bool) list when 'a : comparison
let merge dtl1 dtl2 =
    let dts1 = Set.ofList dtl1
    let dts2 = Set.ofList dtl2

    let dts1Only = dts1 - dts2
    let dts2Only = dts2 - dts1 
    let dtsBoth = Set.intersect dts1 dts2

    [
        for dt in dts1Only do
            yield (dt,true,false)

        for dt in dts2Only do
            yield (dt,false,true)

        for dt in dtsBoth do
            yield (dt,true,true)
    ]

Here’s an example:

let dtl1 = 
   [DateTime.Today.AddDays(1.)
    DateTime.Today.AddDays(2.)
    DateTime.Today.AddDays(3.)
    DateTime.Today.AddDays(4.)
    DateTime.Today.AddDays(5.)
    DateTime.Today.AddDays(6.)]

let dtl2 = 
   [DateTime.Today.AddDays(4.)
    DateTime.Today.AddDays(5.)
    DateTime.Today.AddDays(6.)
    DateTime.Today.AddDays(7.)
    DateTime.Today.AddDays(8.)
    DateTime.Today.AddDays(9.)]

merge dtl1 dtl2