Question

This blog post (http://williamedwardscoder.tumblr.com/post/18319031919/programming-language-readability) contains implementation of autocompletion in Haskell and Python to compare the readability of the programming languages.

Curious to find out how to implement the same in Clojure. Will Clojure codes be more readable due to its greater abstraction ability?

Answer 1

A minimalist implementation:

(ns trie.example)

(defn trie-add [trie & words]
  (reduce
   (fn [trie word]
     (assoc-in trie (concat word [::val]) word))
   trie
   words))

(defn trie-matches [trie prefix]
  (letfn [(search [node]
            (mapcat (fn [[k v]]
                      (if (= ::val k) [v] (search v)))
                    node))]
    (search (get-in trie prefix))))

Example usage:

;; Create trie
(def trie (trie-add {} "foo" "ba" "bar" "baz" "qux" "quux"))

;; trie looks like this:
{\q
 {\u
  {\u {\x {:trie.example/val "quux"}},
   \x {:trie.example/val "qux"}}},
 \b
 {\a
  {\z {:trie.example/val "baz"},
   \r {:trie.example/val "bar"},
   :trie.example/val "ba"}},
 \f {\o {\o {:trie.example/val "foo"}}}}

;; Autocomplete
(trie-matches trie "ba")
=> ("baz" "bar" "ba")

Things like sorting, storing non-word values, and compression are left as an exercise to the reader.