Question

This command prints:

$ echo "123456789" | awk '{ print substr ($1,1,4) }'
1234

Is it possible to execute a string as command? For example, this command:

echo "123456789" | awk '{a="substr"; print a ($1,1,4) }'

Result:

$ echo "123456789" | awk '{a="substr"; print a ($1,1,4) }'
awk: {a="substr"; print a ($1,1,4) }
awk:                               ^ syntax error

EDIT:

$ cat tst.awk 
function my_substr(x,y,z) { return substr(x,y,z) }

{ a="my_substr"; print @a($1,1,4) }
bolek@bolek-desktop:~/Pulpit$ echo "123456789" | gawk -f tst.awk
gawk: tst.awk:3: { a="my_substr"; print @a($1,1,4) }
gawk: tst.awk:3:                        ^ nieprawidłowy znak '@' w wyrażeniu
bolek@bolek-desktop:~/Pulpit$ 

Answer 1

You can call user-defined functions via variables in GNU awk using indirect function calls, see http://www.gnu.org/software/gawk/manual/gawk.html#Indirect-Calls

$ cat tst.awk
function foo() { print "foo() called" }
function bar() { print "bar() called" }

BEGIN {
   the_func = "foo"
   @the_func()

   the_func = "bar"
   @the_func()
}
$ gawk -f tst.awk
foo() called
bar() called

Unfortunately due to internal implementation issues, if you want to call builtin functions that way then you need to write a wrapper for each:

$ cat tst.awk
function my_substr(x,y,z) { return substr(x,y,z) }

{ a="my_substr"; print @a($1,1,4) }
$ echo "123456789" | gawk -f tst.awk
1234