Question

This is my first run through with PL SQL so I might be making some sort of silly error.
I am trying to write a procedure in Oracle Express Edition 11g. I am running into an error that has to do with my WITH clause in the procedure body.

Whenever I try and run it I see two errors.

Error report:
ORA-06550: line 14, column 50:
PL/SQL: ORA-00918: column ambiguously defined
ORA-06550: line 12, column 7:
PL/SQL: SQL Statement ignored
ORA-06550: line 29, column 3:
PLS-00306: wrong number or types of arguments in call to 'FIND_HIGH_AVG'
ORA-06550: line 29, column 3:
PL/SQL: Statement ignored
06550. 00000 -  "line %s, column %s:\n%s"
*Cause:    Usually a PL/SQL compilation error.
*Action:

Code for the procedure is found below.

DECLARE 
  myTerm courses.term%type;
  myLine courses.lineno%type;

procedure find_high_avg (term IN courses.term%type, 
                        line IN courses.lineno%type,
                        s_fname OUT students.fname%type,
                        s_lname OUT students.lname%type,
                        s_sid OUT students.side%type,
                        s_avg OUT number) is 
  begin 
      WITH grades as (select * from components co --line 12 here
            join scores sc on co.term = sc.term and co.lineno = sc.lineno and CO.COMPNAME = SC.COMPNAME
            where sc.lineno = line and sc.term = term) --line 14 here
      select * 
      into s_fname, s_lname, s_sid, s_avg 
      from (
          select s.fname, s.lname, s.sid, round(sum(points/maxpoints * weight),0) as AV
          from grades, students
          join students s on grades.sid = s.sid
          group by s.sid, s.fname, s.lname
          order by AV)
      where rownum = 1;   
  end; 

BEGIN
  myTerm:='F12';
  myLine:='1031';
  find_high_avg(myTerm, myLine); --line 29 here
END;

Answer 1

The error at line 10 occurs because parameters to stored procedures do not take a length. The procedure declaration should be something like

procedure find_high_avg (term IN courses.term%type, 
                        line IN courses.lineno%type,
                        s_fname OUT students.fname%type,
                        s_lname OUT students.lname%type,
                        s_sid OUT students.side%type,
                        average OUT number) 
is

The error at line 14 is likely because the parameters to your procedure have the same name as columns in your table. In a SQL statement’s scope resolution rules, column names take precedence over local PL/SQL variables. So when you code something like

sc.term = term

Oracle tries to resolve the unqualified TERM using a column in one of the tables. If both tables have a column named TERM, that generates an ambiguous column reference– Oracle doesn’t know which of the two tables to use. Of course, in reality, you don’t want it to use the column from either table, you want it to use the parameter. The most common approach to this problem is to add a prefix to your parameter names to ensure that they do not collide with the column names. Something like

procedure find_high_avg (p_term IN courses.term%type, 
                        p_line IN courses.lineno%type,
                        s_fname OUT students.fname%type,
                        s_lname OUT students.lname%type,
                        s_sid OUT students.side%type,
                        p_average OUT number) 
is

The error on line 29 occurs because the procedure takes 6 parameters– 2 IN and 4 OUT. In order to call it, therefore, you would need to use 6 parameters. Something like

DECLARE 
  myTerm courses.term%type;
  myLine courses.lineno%type;

  l_fname students.fname%type;
  l_lname students.lname%type;
  l_sid   students.side%type;
  l_avg   number;
BEGIN
  myTerm:='F12';
  myLine:='1031';
  find_high_avg(myTerm, myLine,l_fname,l_lname, l_sid, l_avg); 
END;