Question

This is the mock module I’m using:

http://metacpan.org/pod/Test::MockModule

How to mock sub a to sub b,

where sub b just does something else before call sub a?

sub b {
  #do something else
  a(@_);
}

Answer 1

You can grab the un-mocked method with can ( UNIVERSAL::can ). After that you can either goto it or just use the ampersand calling style to pass the same arguments. That’s what I did below.

 my $old_a = Package::To::Be::Mocked->can( 'a' );
 $pkg->mock( a => sub { 
      # do some stuff
      &$old_a;
 });

This of course assumes that your sub isn’t AUTOLOAD or generated through AUTOLOAD without redefining can. (I learned years back that if you’re going to mess with AUTOLOAD, it’s probably best to do the work in can.)

You could also create your own utility that does this automatically, by invading modifying the Test::MockModule‘s namespace.

{   package Test::MockModule;
    sub modify {
        my ( $self, $name, $modfunc ) = @_;
        my $mock_class = $self->get_package();
        my $old_meth = $mock_class->can( $name );
        croak( "Method $name not defined for $mock_class!" ) unless $old_meth;
        return $self->mock( $name => $modfunc->( $old_meth ));
    }
}

And you could call it like so:

$mock->modify( a => sub { 
    my $old_a = shift;
    return sub { 
        my ( $self ) = @_;
        # my stuff and I can mess with $self
        local $Carp::CarpLevel += 1;
        my @returns = &$old_a;
        # do stuff with returns
        return @returns;
    };
});