Question

This question may seem strange. However I’m in the need of interacting with an application that is releasing worldwide with different names, eg. AppEN, AppGB, AppDE etc…

I am looking for a solution that allow me to use this command:

tell application process "AppnameGB"

However it should work with all the different variations of this application. I don’t know if this is possible but searching for a string in the application name could do the trick: tell application process that contain in its name “Appname”.

Answer 1

If the process is already open, you can use something like this:

tell application "System Events"
    tell (process 1 where name starts with "TextEd")
        properties
        set f to its file
    end tell
end tell
tell application (f as text)
    properties
end tell

Telling Finder to list files is really slow:

tell application "Finder"
    item 1 of (path to applications folder) where name starts with "Text"
end tell

You can use do shell script though:

set a to do shell script "ls /Applications/ | grep -m1 '^Text.*\\.app$'"
tell application a
    properties
end tell

set a to do shell script "mdfind 'kMDItemContentType==com.apple.application-bundle&&kMDItemFSName==Text*' | head -n1" would also search outside the applications folder.