Home/ Questions/Q 566389
In Process

The Archive Base Latest Questions

Editorial Team
  • 0
Asked: 2026-05-13T12:58:19+00:00

this question relates to XSLT to generate html tags specified in XML where I

  • 0

this question relates to

XSLT to generate html tags specified in XML

where I had an xml docment and used an xsl to generate html tags using 

<xsl:element name="{Type}" >

the problem I have is that I want to specify some html attributes in my xml for example

<Page>
  <ID>Site</ID>
  <Object>
    <ID>PostCode</ID>
    <Type>div</Type>
    <Attributes>
       <Attribute name="class">TestStyle</Attribute>
       <Attribute name="id">TestDiv</Attribute>
    </Attributes>
    <Class>display-label</Class>
    <Value>PostCode</Value>
  </Object>
</Page>

So does any one know how I could populate the xsl:element with the two attributes using xsl?

Thanks

Share

Leave an answer

You must login to add an answer.

Need An Account,

1 Answer

  1. Editorial Team

    Building from the stylesheet that I posted in the previous question, within the element declaration you can iterate through each of the Attributes/Attribute elements and construct the attributes for the element that you are constructing.

    You are “standing” on the Object element node inside that for-loop, so you can then iterate over it’s Attributes/Attribute elements like this:

    <xsl:for-each select="Attributes/Attribute">
  <xsl:attribute name="{@name}"><xsl:value-of select="current()"/></xsl:attribute>
</xsl:for-each>

    Applied to your stylesheet:

    <?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
  <xsl:output method="html" indent="yes"/>
  <xsl:template match="/">
    <html>
      <head>
      </head>
      <body>
        <xsl:for-each select="Page/Object">
            <xsl:element name="{Type}" >
                <xsl:for-each select="Attributes/Attribute">
                    <xsl:attribute name="{@name}"><xsl:value-of select="current()"/></xsl:attribute>
                </xsl:for-each>
                <xsl:value-of select="Value"/>
            </xsl:element>
        </xsl:for-each>
      </body>
    </html>
  </xsl:template>
</xsl:stylesheet>

    This is an alternative way to achieve the same output, but in a little more delcarative fashion, using apply-templates instead of for-each.

    <?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
  <xsl:output method="html" indent="yes"/>
  <xsl:template match="/">
    <html>
      <head>
      </head>
      <body>
        <xsl:apply-templates select="Page/Object" />
      </body>
    </html>
  </xsl:template>

  <xsl:template match="Object">
    <xsl:element name="{Type}" >
       <xsl:apply-templates select="Attributes/Attribute" />
       <xsl:apply-templates select="Value" />
    </xsl:element>
  </xsl:template>

  <xsl:template match="Attribute">
     <xsl:attribute name="{@name}"><xsl:value-of select="."/></xsl:attribute>
  </xsl:template>

</xsl:stylesheet>
    • 0