Home/ Questions/Q 910903
In Process

The Archive Base Latest Questions

Editorial Team
  • 0
Asked: 2026-05-15T17:06:57+00:00

This stems from a related discussion, How to subtract specific elements in a list

  • 0

This stems from a related discussion, How to subtract specific elements in a list using functional programming in Mathematica?

How does one go about easily calculating percent differences between values in a list?

The linked question uses Differences to easily calculate absolute differences between successive elements in a list. However easy the built-in Differences function makes that particular problem, it still leaves the question as to how to perform different manipulations.

As I mentioned earlier, I am looking to now calculate percent differences. Given a list of elements, {value1, value2, ..., valueN}, how does one perform an operation like (value2-value1)/value1 to said list?

I’ve tried finding a way to use Slot or SlotSequence to isolate specific elements and then apply a custom function to them. Is this the most efficient way to do something like this (assuming that there is a way to isolate elements and perform operations on them)?

Share

Leave an answer

You must login to add an answer.

Need An Account,

1 Answer

  1. Editorial Team

    There are a few natural ways to do it.

    You could form the list of arguments to your “percentage decrease” function using Partition:

    In[3]:= list = {a, b, c, d, e};

In[4]:= Partition[list, 2, 1]

Out[4]= {{a, b}, {b, c}, {c, d}, {d, e}}

    Then you can Apply a function to these:

    In[6]:= f @@@ Partition[list, 2, 1]

Out[6]= {f[a, b], f[b, c], f[c, d], f[d, e]}

    Using your percent decrease function:

    In[7]:= PercentDecrease[a_, b_] := (b - a)/a

In[8]:= PercentDecrease @@@ Partition[list, 2, 1]

Out[8]= {(-a + b)/a, (-b + c)/b, (-c + d)/c, (-d + e)/d}

    (Read about @@@ by looking at the “More Information” notes at Apply.)

    Instead of Partition you can use Most and Rest to form lists of the first and second arguments and then combine them using MapThread:

    In[14]:= MapThread[PercentDecrease, {Most[list], Rest[list]}]

Out[14]= {(-a + b)/a, (-b + c)/b, (-c + d)/c, (-d + e)/d}

    A different way is to form your operation (a subtraction and a division) in two steps like this:

    In[10]:= Differences[list] / Most[list]

Out[10]= {(-a + b)/a, (-b + c)/b, (-c + d)/c, (-d + e)/d}

    The divide operation (/) threads over the two lists Differences[list] and Most[list].

    • 0