Question

To flip an image around the center i am using this piece of code:

        // Calculate offset
        var offsetWidth:Number = image.contentWidth/2.0;
        var offsetHeight:Number =  image.contentHeight/2.0;
        // Perform flip
        var matrix:Matrix = new Matrix();
        matrix.translate(-offsetWidth, -offsetHeight);
        if(direction=="HORIZONTAL"){
            matrix.scale(-1, 1);
        }else if(direction=="VERTICAL"){
            matrix.scale(1,-1)
        }
        matrix.translate(+offsetWidth, +offsetHeight);
        matrix.concat(image.transform.matrix);
        image.transform.matrix = matrix.clone();

which works fine.But my problem is when i try to get the BitmapData from the image like this:

        var bitmapData:BitmapData = new BitmapData(image.width,image.height); 
        bitmapData.draw(image);

and use the bitmapData as source for another image,no image is displayed.Broken image icon appears.
Also i am rotating the image around center and using similar code as mentioned below and its working fine and i am able to copy the bitmapdata to another image..here’s the code for reference:

   var matrix:Matrix = new Matrix(); 
   matrix.rotate(Math.PI/2); 
   matrix.tx = img.content.height; 
   var bd:BitmapData = new BitmapData(img.content.height, img.content.width);   
   bd.draw(img.content, matrix);

Please help regarding the same.

Answer 1

Answer is in the question.

In the second case you are using matrix

bd.draw(img.content, matrix);

Similarly do for the flip

bitmapData.draw(image, matrix);

EDIT:

Calculation of the translation for the matrix in flipping is not correct. Both the translation on X and Y are needed only when you flip horizontally and vertically.
Please find the code below in which it is working.

package
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.display.StageScaleMode;
    import flash.geom.Matrix;
    import flash.geom.Rectangle;

    [SWF(width="640", height="480")]

    public class FlipRotate extends Sprite
    {
        [Embed(source="away3d.jpg")]
        private var Pic:Class;


        public function FlipRotate()
        {
            super();

            stage.scaleMode = StageScaleMode.NO_SCALE;


            var sourceImage:Bitmap;
            var targetImage:Bitmap;

            sourceImage = new Pic();

            //flip(sourceImage, "BOTH");
            flip(sourceImage, "VERTICAL");
            //flip(sourceImage, "BOTH");

            rotate(sourceImage, Math.PI/3);



            targetImage = new Bitmap();

            /* Get the current bounds of source image to calculate the dimenstion of new image
             Apply translation to bring the content outside into view in new image */
            var bounds:Rectangle = sourceImage.getBounds(this);
            var matrix:Matrix = sourceImage.transform.matrix;
            matrix.translate(-bounds.x, -bounds.y);

            /* Draw in new image applying translated matrix of source imgae */
            targetImage.bitmapData = new BitmapData(bounds.width, bounds.height);
            targetImage.bitmapData.draw(sourceImage, matrix);

            /* Add new image and postion at the center of stage */
            addChild(targetImage);
            targetImage.x = (stage.stageWidth-targetImage.width)/2;
            targetImage.y = (stage.stageHeight-targetImage.height)/2;

        }

        public function flip(image:Bitmap, direction:String):void{

            var matrix:Matrix = image.transform.matrix;

            if(direction=="HORIZONTAL"){
                matrix.scale(-1, 1);
                matrix.translate(image.width, 0);
            }else if(direction=="VERTICAL"){
                matrix.scale(1,-1);
                matrix.translate(0, image.height);
            }else if(direction == "BOTH"){
                matrix.scale(-1,-1);
                matrix.translate(image.width, image.height);
            }

            image.transform.matrix = matrix;

        }   

        public function rotate(image:Bitmap, angle:Number):void{

            var matrix:Matrix = image.transform.matrix;

            matrix.translate(-image.width/2, -image.height/2);
            matrix.rotate(angle); 
            matrix.translate(image.width/2, image.height/2);

            image.transform.matrix = matrix;

        }   


    }
}