Question

Tree traversal refers to the process of visiting each node in a tree data structure in a systematic way. The preorder traversal in the following image

Sorted_binary_tree

returns F, B, A, D, C, E, G, I, H (root, left, right). This is the Prolog code:

preorder(tree(X,L,R),Xs) :-
    preorder(L,Ls),
    preorder(R,Rs),
    append([X|Ls],Rs,Xs).
preorder(void,[]).

I would write a prolog program that returns

F, B, A, F,B,D, C,F,B,D, E,F, G, I, H

that is, the paths of the tree. Any suggestions?

Answer 1

Try this out for size:

dfs_paths(tree(X, void, void), [X]) :- !.
dfs_paths(tree(X, L, _R), [X|Xs]) :-
    dfs_paths(L, Xs).
dfs_paths(tree(X, _L, R), [X|Xs]) :-
    dfs_paths(R, Xs).

Testing it out with a fact representing the tree from here:

tree(T) :- T = tree(f, tree(b, tree(a,void,void), tree(d,tree(c,void,void),tree(e,void,void))), tree(g, void, tree(i, tree(h,void,void),void))).

Trying it out (without showing bindings for T):

?- tree(T), dfs_paths(T, L).
L = [f, b, a] ;
L = [f, b, d, c] ;
L = [f, b, d, e] ;
L = [f, g, i, h] 

Note that dfs_paths/2 backtracks to give you the alternate paths. If you wanted a list of them all up front, you could try:

?- tree(T), findall(P, dfs_paths(T, P), Ps).
Ps = [[f, b, a], [f, b, d, c], [f, b, d, e], [f, g, i, h]].

If you wanted a flat list of terms as you’ve written above, you can flatten/2 the result.