Question

Using Coldfusion 8 has anyone been able to either embed images into a excel spreadsheet (xlsx) or link them via img src?

Some background info: The cf server will pickup an excel document with product rows. Based on the product id and style etc, I be able to find or create an image that gets added as the first column into the existing excel doc.

I know coldfusion 9 has a function called SpreadsheetAddImage, unfortunately I’m on cf 8 with no chance to upgrade.

Answer 1

I am not sure what you are currently using to manipulate the xlsx files. However, the spreadsheet functionality in CF9 utilizes POI, which can obviously be used from CF8 as well. It just requires a little more low level code.

Pre-requisites:

Though POI is bundled with CF8, it is an old version. You need a newer version to manipulate .xlsx files. You can either use the javaLoader -OR- replace the existing jars in {cf_root}\lib folder. Note, I do not know if replacing the jars has any negative side effects.

Adding Images:

Excel does not really support <img> tags, only hyperlinks. However, you can embed images within the workbook like SpreadsheetAddImage does. As outlined in the POI’s Busy Developers Guide, the basic process is:

1. Load the xlsx file with the WorkBookFactory
2. Grab the binary of each image and add it to the workbook
3. Anchor each image to the desired cells
4. Save the modified workbook to back to disk

Example:

---

<cfscript>
    // .. 

    // load the xlsx file with the javaLoader
    factory = loader.create("org.apache.poi.ss.usermodel.WorkbookFactory");
    input = loader.create("java.io.FileInputStream").init( "c:/path/to/someFile.xlsx" );
    workbook = factory.create( input );
    input.close();

    // get the desired sheet and load helper objects (once)
    sheet     = workbook.getSheet("Your Sheet Name");
    patriarch = sheet.createDrawingPatriarch();
    helper    = workbook.getCreationHelper();

    // add the image to the workbook
    imageBytes  = fileReadBinary( "c:/path/to/someImage.jpg" );
    imageIndex  = workbook.addPicture( imageBytes, workbook.PICTURE_TYPE_JPEG );

    // anchor the picture to the first cell ie A1
    anchor     = helper.createClientAnchor();
    anchor.setRow1( javacast("int", 0) ); // row of first cell (zero based)
    anchor.setCol1( javacast("int", 0) ); // column of first cell (zero based)
    picture = patriarch.createPicture( anchor, imageIndex );
    picture.resize(); // only supported for jpg and png

    // save it back to disk
    outstream = loader.create("java.io.FileOutputStream").init( "c:/path/to/outFile.xlsx"" );
    workbook.write( outstream );
    outstream.flush();
    outstream.close(); 
</cfscript>

---

New Columns
Ironically, inserting a new column is trickier than adding an image. Last I checked, POI still lacked a built in function for inserting new columns. So you would need to shift all existing cells to the right before inserting the images into the first column. The tricky part is maintaining cell formats, merged cells, etcetera.