Question

Using Haskell, I’m writing a function that counts the total number of leaves in a tree. I have defined the tree as so:

data Tree a = Leaf | Node a (Tree a) (Tree a)

I writing a function that does this by:

countL :: Tree a -> Int
countL Leaf = 1
countL (Node x tL tR) = (countL tL) + (countL tR)

This works but I want to take it a step further by doing the same thing using the fold function. I’ve having a working fold function for trees that I defined by doing:

mytFold :: (a -> b -> b -> b) -> b -> Tree a -> b
mytFold f g Leaf = g
mytFold f g (Node a xl xr) = f a (mytFold f g xl) (mytFold f g xr)

I tried to include the fold function (also used a helper function that I defined by doing this:

countL' :: Tree a -> Integer
countL' Leaf = 1
countL' = mytFold leafy 0 where
        leafy tL tR = tL + tR

But I’m getting some weird errors. Does anyone have any insight on what’s wrong?

Answer 1

There are two syntactic/type problems. Firstly, every top level binding must have the same number of arguments, so

countL' Leaf = ..
countL' = ..

isn’t valid. One solution is

countL' Leaf = ..
countL' tree = mytFold leafy 0 tree

Once you’ve done this, then GHC gives you an error like

    Couldn't match expected type `Integer -> Integer'
                with actual type `Integer'
    Expected type: Integer -> Integer -> Integer -> Integer
      Actual type: Integer -> Integer -> Integer
    In the first argument of `mytFold', namely `leafy'
    In the expression: mytFold leafy 0 tree

Which is because mytFold requires a 3-argument function as its first argument, and leafy just takes 2. Fix this by using leafy _ tL tR = tL + tR.

---

However, once you have done this, you will see that this gives the wrong answer: countL' (Node 1 Leaf Leaf) == 0. A way that might make the solution clear is to removing the countL' Leaf case, and trying to write countL as just the fold. i.e.

countL'' = mytFold f a

where you have do decide what f and a are (hint: you already have f == leafy == const (+)). Consider mytFold leafy a Leaf.